Package the native plugin workbench helper

pkgbuilds/omarchy-discovery/.omarchy/package.json

@@ -0,0 +1,4 @@
+{
+  "source": "local",
+  "release_ring": "fast"
+}

pkgbuilds/omarchy-discovery/PKGBUILD

@@ -0,0 +1,41 @@
+pkgname=omarchy-discovery
+pkgver=0.3.0
+pkgrel=1
+pkgdesc='Native Omarchy discovery and ecosystem management helper'
+arch=('x86_64' 'aarch64')
+url='https://github.com/tcballard/omarchy-plugin-workbench'
+license=('MIT')
+depends=('gcc-libs' 'glibc' 'git' 'curl')
+makedepends=('cargo')
+provides=('omarchy-plugin-workbench')
+conflicts=('omarchy-plugin-workbench')
+
+_commit='0d3c38085a0da6021842f29fbd2b6c2bd451d49a'
+_srcdir="omarchy-plugin-workbench-$_commit"
+source=("$pkgname-$_commit.tar.gz::$url/archive/$_commit.tar.gz")
+sha256sums=('1d91e1c3856a54893c9df6a81bd5016fb0cb0f76781e99794a56a9a352d0ed86')
+
+prepare() {
+  cd "$_srcdir"
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "$_srcdir"
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release
+}
+
+check() {
+  cd "$_srcdir"
+  export CARGO_TARGET_DIR=target
+  cargo test --frozen --all-targets --all-features
+}
+
+package() {
+  cd "$_srcdir"
+  install -Dm755 target/release/omarchy-discovery \
+    "$pkgdir/usr/bin/omarchy-discovery"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
+}