feat(omafiles): add keyboard-driven file explorer

pkgbuilds/omafiles/.omarchy/package.json

@@ -0,0 +1,3 @@
+{
+  "source": "local"
+}

pkgbuilds/omafiles/PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: This_Is_NPC <gabrielfollone27@gmail.com>
+
+pkgname=omafiles
+pkgver=0.1.0
+pkgrel=1
+pkgdesc='Tag files and list them by tag, from a command line and a Qt Quick window'
+arch=('x86_64' 'aarch64')
+url='https://github.com/This-Is-NPC/omafiles'
+license=('MIT')
+install='omafiles.install'
+options=('!debug')
+depends=(
+  'hicolor-icon-theme'
+  'qt6-base'
+  'qt6-declarative'
+  'xdg-desktop-portal'
+  'xdg-utils'
+  'glib2'
+)
+makedepends=(
+  'gcc'
+  'make'
+  'qt6-base'
+  'qt6-declarative'
+)
+source=("$pkgname-$pkgver.tar.gz::https://github.com/This-Is-NPC/omafiles/archive/refs/tags/v$pkgver.tar.gz")
+sha256sums=('047f2edc18c78b0566bbfcdcb2a58155245306814ce34f07ed424ef4d16d4a36')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  mkdir -p build
+  cd build
+  qmake6 "../omafiles.pro"
+  make -j"$(nproc)"
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  install -Dm755 build/bin/omafiles "$pkgdir/usr/bin/omafiles"
+  install -Dm755 build/bin/omafiles-studio "$pkgdir/usr/bin/omafiles-studio"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 pkgbuild/omafiles.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/omafiles.svg"
+  install -Dm644 pkgbuild/omafiles.desktop "$pkgdir/usr/share/applications/omafiles.desktop"
+}

pkgbuilds/omafiles/omafiles.install

@@ -0,0 +1,12 @@
+post_install() {
+  command -v update-desktop-database >/dev/null 2>&1 && update-desktop-database -q
+  command -v gtk-update-icon-cache >/dev/null 2>&1 && gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}