Develop

.gitignore

@@ -0,0 +1,17 @@
+.terraform/
+
+*.tfstate
+*.tfstate.*
+
+*.tfvars
+*.tfvars.json
+
+.terraformrc
+terraform.rc
+
+*.tfplan
+*.log
+
+.DS_Store
+
+id_rsa*

backend.tf

@@ -0,0 +1,9 @@
+terraform {
+  backend "azurerm" {
+    resource_group_name  = "mate-azure-task-12"
+    storage_account_name = "yourstorageaccount"
+    container_name       = "tfstate"
+    key                  = "terraform.tfstate"
+    use_oidc             = true
+  }
+}

install-app.sh

@@ -9,11 +9,12 @@
 # when running the script as VM extention.  
 apt-get update -yq
 apt-get install python3-pip -yq
+apt-get install -yq git
 
-# Create a directory for the app and download the files. 
-mkdir /app 
+# Create a directory for the app and download the files.
+mkdir -p /app
 # make sure to uncomment the line bellow and update the link with your GitHub username
-# git clone https://github.com/<your-gh-username>/azure_task_12_deploy_app_with_vm_extention.git
+git clone https://github.com/salabam/devops_todolist_terraform_task.git
 cp -r devops_todolist_terraform_task/app/* /app
 
 # create a service for the app via systemctl and start the app

main.tf

@@ -0,0 +1,58 @@
+terraform {
+  required_providers {
+    random = {
+      source  = "hashicorp/random"
+      version = "~> 3.0"
+    }
+    azurerm = {
+      source  = "hashicorp/azurerm"
+      version = "3.105.0"
+    }
+  }
+}
+
+provider "azurerm" {
+  features {}
+  use_oidc = true
+}
+
+resource "azurerm_resource_group" "rg" {
+  name     = var.resource_group_name
+  location = var.location
+}
+
+module "storage_module" {
+  source                 = "./modules/storage"
+  storage_account_name   = var.storage_account_name
+  storage_container_name = var.storage_container_name
+  resource_group_name    = azurerm_resource_group.rg.name
+  location               = var.location
+}
+
+module "network_module" {
+  source                  = "./modules/network"
+  resource_group_name     = azurerm_resource_group.rg.name
+  location                = azurerm_resource_group.rg.location
+  virtual_network_name    = var.virtual_network_name
+  vnet_address_prefix     = var.vnet_address_prefix
+  subnet_name             = var.subnet_name
+  subnet_address_prefix   = var.subnet_address_prefix
+  net_security_group_name = var.net_security_group_name
+  public_ip_name          = var.public_ip_name
+  dns_prefix              = var.dns_prefix
+}
+
+module "compute_module" {
+  source                       = "./modules/compute"
+  resource_group_name          = azurerm_resource_group.rg.name
+  location                     = azurerm_resource_group.rg.location
+  subnet_id                    = module.network_module.subnet_id
+  public_ip_id                 = module.network_module.public_ip_id
+  network_interface_name_sufix = var.network_interface_name_sufix
+  vm_name                      = var.vm_name
+  vm_size                      = var.vm_size
+  admin_username               = var.admin_username
+  ssh_public_key               = var.ssh_public_key
+  install_app_sh_git_path      = var.install_app_sh_git_path
+  depends_on                   = [module.network_module]
+}

modules/compute/main.tf

@@ -0,0 +1,56 @@
+resource "azurerm_network_interface" "ni" {
+  name                = "${var.vm_name}${var.network_interface_name_sufix}"
+  resource_group_name = var.resource_group_name
+  location            = var.location
+
+  ip_configuration {
+    name                          = "ip-cfg"
+    private_ip_address_allocation = "Dynamic"
+    subnet_id                     = var.subnet_id
+    public_ip_address_id          = var.public_ip_id
+  }
+}
+
+resource "azurerm_linux_virtual_machine" "vm" {
+  name                            = var.vm_name
+  location                        = var.location
+  resource_group_name             = var.resource_group_name
+  network_interface_ids           = [azurerm_network_interface.ni.id]
+  size                            = var.vm_size
+  admin_username                  = var.admin_username
+  disable_password_authentication = true
+
+  admin_ssh_key {
+    username   = var.admin_username
+    public_key = var.ssh_public_key
+  }
+
+  os_disk {
+    caching              = "ReadWrite"
+    storage_account_type = "Standard_LRS"
+  }
+
+  source_image_reference {
+    publisher = "Canonical"
+    offer     = "0001-com-ubuntu-server-jammy"
+    sku       = "22_04-lts"
+    version   = "latest"
+  }
+
+}
+
+resource "azurerm_virtual_machine_extension" "install_script" {
+  name                 = "install-app-extension"
+  virtual_machine_id   = azurerm_linux_virtual_machine.vm.id
+  publisher            = "Microsoft.Azure.Extensions"
+  type                 = "CustomScript"
+  type_handler_version = "2.1"
+
+  settings = jsonencode({
+    fileUris = [
+      var.install_app_sh_git_path
+    ],
+    commandToExecute = "bash install-app.sh"
+  })
+}
+

modules/compute/outputs.tf

@@ -0,0 +1,3 @@
+output "vm_id" {
+  value = azurerm_linux_virtual_machine.vm.id
+}

modules/compute/variables.tf

@@ -0,0 +1,52 @@
+### I made sure that all variables are in terraform.tfvars
+### I don't need you to write "check it!" to every variable.
+
+variable "resource_group_name" {
+  description = "The name of the resource group"
+  type        = string
+}
+
+variable "location" {
+  description = "The location for all resources."
+  type        = string
+}
+
+variable "vm_name" {
+  description = "The name of the virtual machine"
+  type        = string
+}
+
+variable "vm_size" {
+  description = "The size of the virtual machine"
+  type        = string
+}
+
+variable "network_interface_name_sufix" {
+  description = "The sufix of the network interface, will be concatenated with vm_name"
+  type        = string
+}
+
+variable "subnet_id" {
+  description = "The id of the sub network"
+  type        = string
+}
+
+variable "public_ip_id" {
+  description = "The id of the public ip address"
+  type        = string
+}
+
+variable "admin_username" {
+  description = "The user that will be created when the virtual machine is created"
+  type        = string
+}
+
+variable "ssh_public_key" {
+  description = "The path to the ssh key for sign in to system"
+  type        = string
+}
+
+variable "install_app_sh_git_path" {
+  description = "The path to the git repo with install script"
+  type        = string
+}

modules/network/locals.tf

@@ -0,0 +1,37 @@
+locals {
+  security_rules = [
+    {
+      name                       = "AllowSSH"
+      priority                   = 100
+      direction                  = "Inbound"
+      access                     = "Allow"
+      protocol                   = "Tcp"
+      source_port_range          = "*"
+      destination_port_range     = "22"
+      source_address_prefix      = "*"
+      destination_address_prefix = "*"
+    },
+    {
+      name                       = "AllowHTTP"
+      priority                   = 110
+      direction                  = "Inbound"
+      access                     = "Allow"
+      protocol                   = "Tcp"
+      source_port_range          = "*"
+      destination_port_range     = "80"
+      source_address_prefix      = "*"
+      destination_address_prefix = "*"
+    },
+    {
+      name                       = "AllowHTTP8080"
+      priority                   = 120
+      direction                  = "Inbound"
+      access                     = "Allow"
+      protocol                   = "Tcp"
+      source_port_range          = "*"
+      destination_port_range     = "8080"
+      source_address_prefix      = "*"
+      destination_address_prefix = "*"
+    }
+  ]
+}

modules/network/main.tf

@@ -0,0 +1,53 @@
+resource "random_integer" "suffix" {
+  min = 1000
+  max = 9999
+}
+
+resource "azurerm_virtual_network" "vnet" {
+  name                = var.virtual_network_name
+  address_space       = var.vnet_address_prefix
+  resource_group_name = var.resource_group_name
+  location            = var.location
+}
+
+resource "azurerm_subnet" "subnet" {
+  name                 = var.subnet_name
+  address_prefixes     = var.subnet_address_prefix
+  resource_group_name  = var.resource_group_name
+  virtual_network_name = azurerm_virtual_network.vnet.name
+}
+
+resource "azurerm_public_ip" "pip" {
+  name                = var.public_ip_name
+  location            = var.location
+  resource_group_name = var.resource_group_name
+  allocation_method   = "Dynamic"
+  sku                 = "Standard"
+  domain_name_label   = "${var.dns_prefix}${random_integer.suffix.result}"
+}
+
+resource "azurerm_network_security_group" "nsg" {
+  name                = var.net_security_group_name
+  location            = var.location
+  resource_group_name = var.resource_group_name
+
+  dynamic "security_rule" {
+    for_each = local.security_rules
+    content {
+      name                       = security_rule.value.name
+      priority                   = security_rule.value.priority
+      direction                  = security_rule.value.direction
+      access                     = security_rule.value.access
+      protocol                   = security_rule.value.protocol
+      source_port_range          = security_rule.value.source_port_range
+      destination_port_range     = security_rule.value.destination_port_range
+      source_address_prefix      = security_rule.value.source_address_prefix
+      destination_address_prefix = security_rule.value.destination_address_prefix
+    }
+  }
+}
+
+resource "azurerm_subnet_network_security_group_association" "assoc" {
+  subnet_id                 = azurerm_subnet.subnet.id
+  network_security_group_id = azurerm_network_security_group.nsg.id
+}

modules/network/outputs.tf

@@ -0,0 +1,15 @@
+output "public_ip_fqdn" {
+  value = azurerm_public_ip.pip.fqdn
+}
+
+output "subnet_id" {
+  value = azurerm_subnet.subnet.id
+}
+
+output "public_ip_id" {
+  value = azurerm_public_ip.pip.id
+}
+
+output "public_ip_address" {
+  value = azurerm_public_ip.pip.ip_address
+}