skim/flake.nix at master · worktrunk-bot/skim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
{
  description = "Nix flake for skim development";

  inputs.nixpkgs.url = "https://channels.nixos.org/nixpkgs-unstable/nixexprs.tar.xz";

  outputs =
    inputs:
    let
      inherit (inputs.nixpkgs) lib;
      systems = lib.systems.flakeExposed;
      eachSystem = lib.genAttrs systems;
      pkgsFor =
        system:
        import inputs.nixpkgs {
          inherit system;
          config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [ "vagrant" ];
        };
    in
    {
      devShells = eachSystem (
        system:
        let
          pkgs = pkgsFor system;

          # --- package groups -------------------------------------------------------
          base = with pkgs; [
            rustup
            just
          ];
          tests = with pkgs; [
            cargo-nextest
            cargo-insta
            cargo-llvm-cov
            cargo-fuzz
            tmux
          ];
          utils = with pkgs; [
            hyperfine
            cargo-edit
            cargo-public-api
            cargo-msrv
            git-cliff
            cargo-dist
            cargo-cross
            cargo-xwin
            gnuplot
            llvm
            cargo-bloat
            cargo-public-api
          ];
          gungraun = with pkgs; [
            valgrind
            libclang
            binutils
          ];
          vagrantDeps = with pkgs; [
            vagrant
            rsync
          ];

          # --- shell hooks (only groups that need env vars) -------------------------
          gungraunHook = ''
            export LIBCLANG_PATH="${pkgs.libclang.lib}/lib"
            export LD_LIBRARY_PATH="${pkgs.valgrind.out}/lib:$LD_LIBRARY_PATH"
          '';
          vagrantHook = ''
            export VAGRANT_LIBVIRT_OVMF_CODE="${pkgs.OVMF.fd}/FV/OVMF_CODE.fd"
          '';

          mkShell = packages: shellHook: pkgs.mkShellNoCC { inherit packages shellHook; };
        in
        {
          default = mkShell base "";
          tests = mkShell (base ++ tests) "";
          utils = mkShell (base ++ utils) "";
          dev = mkShell (base ++ tests ++ utils) "";
          gungraun = mkShell (base ++ gungraun) gungraunHook;
          vagrant = mkShell (base ++ vagrantDeps) vagrantHook;
          full = mkShell (base ++ tests ++ utils ++ gungraun ++ vagrantDeps) (gungraunHook + vagrantHook);
        }
      );

      formatter = eachSystem (system: (pkgsFor system).nixfmt);
    };
}