editing descriptions in separedit block

[Luis-Henriquez-Perez]

The idea is to edit descriptions at point.

Why is this useful?

• Less visual distraction when editing a description

• Consistent with org mode editing style

If you think about it plain text is kind of like an implicit source block. It differs from headlines and text properties in that it's not really org mode syntax.

• Can separate minor mode that are specifically for prose (spell check, etc)
  with org mode.

org mode buffer. Point is designated by "|".

* hello

|hello world

this is a description

#+begin_src elisp
#+end_src elisp

Separedit buffer after calling separedit-edit-description

|hello world

this is a description

[twlz0ne]

It looks a bit weird.

Basically, you can edit anything region you want. In these case, the edit region can be detected in following ways:

(let ((beg (save-excursion (org-back-to-heading) (forward-line 1) (point)))
      (end (save-excursion
             (if (or (ignore-errors (org-next-block 1))
                     (let ((point (point)))
                       (org-next-visible-heading 1)
                       (not (= point (point)))))
                 (progn
                   (backward-char 1)
                   (point))
               (point-max)))))
  ...)

[Luis-Henriquez-Perez]

Sorry I accidentally closed this.

I tried to make a more precise paragraph editing function. I put the code I wrote below. The main function is org/edit-description-at-point. Let me know if this is something you would accept as a PR. I understand if you don't want to. Perhaps it's out of the scope of separedit.

List of headline elements

(defun org-element-headline-elements+ ()
  "Return elements only under current headline (not subtree)."
  (interactive)
  (save-excursion
    (unless (org-at-heading-p) (org-back-to-heading))
    (--unfold (when (and it (not (eq (org-element-type it) 'headline)))
                (cons it (ignore-errors (org-forward-element)
                                        (org-element-at-point))))
              (progn (org-down-element)
                     (org-element-at-point)))))

whether an element is a paragraph

    (defun org-element-paragraph-p+ (element)
      "Return non-nil if the current element is a paragraph."
      (eq (org-element-type element) 'paragraph))

point in org element

    (defun org-element-contains-point-p+ (point element)
      "Return non-nil if POINT is inside ELEMENT."
      (and (>= point (org-element-property :begin element))
           (>= (org-element-property :end element) point)))

elements to edit

    (defun org-paragraphs-to-edit+ (point elements)
      "Return a list of paragraphs to be edited."
      (-let* ((elements elements)
              (current (-first (-partial #'org-element-contains-point-p+ point)
                               elements))
              ((front back) (-split-on current elements)))
        (append (-take-while #'org-element-paragraph-p+ (reverse front))
                (list current)
                (-take-while #'org-element-paragraph-p+ back))))

org edit description at point

    (defun org/edit-description-at-point+ ()
      "Edit the description at point."
      (interactive)
      (-let* ((elements (org-element-headline-elements+))
              (paragraphs (or (org-paragraphs-to-edit+ (point) elements)
                              (user-error "no description at point")))
              (beg (org-element-property :begin (-first-item paragraphs)))
              (end (org-element-property :end (-last-item paragraphs))))
        (edit-indirect-region beg end t)))

[twlz0ne]

Sorry for taking so long to reply.

It's a good idea, but I think it's too personal and probably not appropriate to put in the package.

I also have a lot of similar code in my personal configuration: separedit.el#some-extended-usage