dotfiles/flake.nix at master · tarunbod/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
{
  description = "NixOS config";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    nix-darwin.url = "github:nix-darwin/nix-darwin/master";
    nix-darwin.inputs.nixpkgs.follows = "nixpkgs";

    agenix.url = "github:ryantm/agenix";
    agenix.inputs.nixpkgs.follows = "nixpkgs";
    agenix.inputs.darwin.follows = "nix-darwin";

    home-manager.url = "github:nix-community/home-manager/master";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";

    rust-overlay.url = "github:oxalica/rust-overlay";
    rust-overlay.inputs.nixpkgs.follows = "nixpkgs";

    uni-sync-curve.url = "github:tarunbod/uni-sync-curve";
    uni-sync-curve.inputs.nixpkgs.follows = "nixpkgs";
    uni-sync-curve.inputs.rust-overlay.follows = "rust-overlay";

    nushell.url = "github:nushell/nushell?dir=scripts/nix";
    nushell.inputs.nixpkgs.follows = "nixpkgs";
    nushell.inputs.rust-overlay.follows = "rust-overlay";
  };

  outputs =
    {
      nixpkgs,
      nix-darwin,
      agenix,
      home-manager,
      uni-sync-curve,
      nushell,
      ...
    }@inputs:
    let
      buildSystem =
        builder: system: extraModules:
        builder {
          inherit system;
          specialArgs = { inherit agenix nushell inputs; };
          modules = [ ./modules/common.nix ] ++ extraModules;
        };
      nixosSystem =
        system: extraModules:
        buildSystem (nixpkgs.lib.nixosSystem) system (
          [
            ./modules/common-linux.nix
            home-manager.nixosModules.home-manager
            agenix.nixosModules.default
          ]
          ++ extraModules
        );
      darwinSystem =
        extraModules:
        buildSystem (nix-darwin.lib.darwinSystem) "aarch64-darwin" (
          [
            ./modules/common-darwin.nix
            home-manager.darwinModules.home-manager
            agenix.darwinModules.default
          ]
          ++ extraModules
        );
    in
    {
      nixosConfigurations = {
        monkey = nixosSystem "x86_64-linux" [
          ./modules/languages.nix
          uni-sync-curve.nixosModules.default
          ./hosts/monkey/configuration.nix
        ];

        chimp = nixosSystem "aarch64-linux" [
          ./hosts/chimp/configuration.nix
        ];
      };

      darwinConfigurations = {
        TMBP = darwinSystem [
          ./modules/languages.nix
          ./hosts/TMBP/configuration.nix
        ];

        QRLPDYDF2P = darwinSystem [
          ./modules/languages.nix
          ./hosts/QRLPDYDF2P/configuration.nix
        ];
      };
    };
}