cryptominisat/flake.nix at master · stp/cryptominisat · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
{
  description = "an advanced incremental SAT solver";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    cadiback = {
      url = "github:meelgroup/cadiback/main";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    # cadiback already depends on cadical; reuse that exact input rather than
    # declaring our own, so flake.lock pins a single cadical revision.
    cadical.follows = "cadiback/cadical";
  };
  outputs =
    {
      self,
      nixpkgs,
      cadical,
      cadiback,
    }:
    let
      inherit (nixpkgs) lib;
      systems = lib.intersectLists lib.systems.flakeExposed lib.platforms.linux;
      forAllSystems = lib.genAttrs systems;
      nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
      fs = lib.fileset;

      cryptominisat-package =
        {
          stdenv,
          fetchFromGitHub,
          cmake,
          cadiback,
          cadical,
          pkg-config,
          gmp,
          zlib,
        }:
        stdenv.mkDerivation {
          name = "cryptominisat";
          src = fs.toSource {
            root = ./.;
            fileset = fs.unions [
              ./src
              ./CMakeLists.txt
              ./cmake
              ./scripts
              ./cryptominisat5Config.cmake.in
              ./pyproject.toml
            ];
          };

          nativeBuildInputs = [
            cmake
            pkg-config
          ];
          buildInputs = [
            cadiback
            cadical
            gmp
            zlib
          ];
          cmakeFlags = [
            "-Dcadical_DIR=${cadical}"
            "-Dcadiback_DIR=${cadiback}"
          ];
        };
    in
    {
      packages = forAllSystems (
        system:
        let
          cryptominisat = nixpkgsFor.${system}.callPackage cryptominisat-package {
            cadical = cadical.packages.${system}.cadical;
            cadiback = cadiback.packages.${system}.cadiback;
          };
        in
        {
          inherit cryptominisat;
          cryptominisat5 = cryptominisat;
          default = cryptominisat;
        }
      );
    };
}