cloudflare-speed-cli/flake.nix at main · ryankoski/cloudflare-speed-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  };
  outputs =
    { nixpkgs, self, ... }:
    let
      forAllSystems =
        f:
        nixpkgs.lib.genAttrs (nixpkgs.lib.systems.flakeExposed) (
          system:
          f {
            inherit system;
            pkgs = nixpkgs.legacyPackages.${system};
          }
        );

      derivation =
        {
          lib,
          rustPlatform,
        }:

        rustPlatform.buildRustPackage {
          pname = "cloudflare-speed-cli";
          version = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package.version;

          src = ./.;

          cargoLock = {
            lockFile = ./Cargo.lock;
          };

          meta = {
            description = "CLI for internet speed test via cloudflare";
            homepage = "https://github.com/kavehtehrani/cloudflare-speed-cli";
            license = lib.licenses.gpl3Only;
            sourceProvenance = with lib.sourceTypes; [ fromSource ];
            meta.platforms = lib.platforms.all;
            # maintainers = with lib.maintainers; [ ];
            mainProgram = "cloudflare-speed-cli";
          };
        };
    in
    {
      packages = forAllSystems (
        { pkgs, ... }:
        {
          default = pkgs.callPackage derivation { };
        }
      );

      overlays.default = final: prev: {
        cloudflare-speed-cli = self.packages.${prev.stdenv.hostPlatform.system}.default;
      };

      devShell = forAllSystems (
        { pkgs, ... }:
        pkgs.mkShell {
          buildInputs = with pkgs; [
            # Rust toolchain
            cargo
            rustc
            rust-analyzer
            clippy
            rustfmt
          ];
        }
      );
    };
}