installation directory

[ChauhanT]

treesit-auto only installs to the tree-sitter folder in the emacs directory. Is there any way to make it install to a different folder? I have set treesit-extra-load-path but it doesn't affect the installation (I am guessing it works only when treesitter is searching for a grammar on disk). Any suggestions/tips would be very welcome!

[m-vitale]

The problem is here:

(defun treesit-auto--prompt-to-install-package (lang)
  "Ask the user if they want to install a tree-sitter grammar for `LANG'.

Non-nil only if installation completed without any errors."
  (when (cond ((eq t treesit-auto-install) t)
              ((eq 'prompt treesit-auto-install)
               (y-or-n-p (format "Tree-sitter grammar for %s is missing.  Install it from %s? "
                                 (symbol-name lang)
                                 (car (alist-get lang treesit-language-source-alist))))))
    (message "Installing the tree-sitter grammar for %s" lang)
    ;; treesit-install-language-grammar will return nil if the
    ;; operation succeeded and 't if a warning was sent to the
    ;; warning buffer. I don't think this is by design but just
    ;; because of the way `display-warning' works, so this might not
    ;; work in the future.
    (not (treesit-install-language-grammar lang))))

and here:

(defun treesit-auto-install-all ()
  "Install every available, maintained grammar.

See `treesit-auto-langs' and `treesit-auto-install' for
how to modify the behavior of this function."
  (interactive)
  (when-let* ((treesit-language-source-alist (treesit-auto--build-treesit-source-alist))
              (to-install (seq-filter (lambda (lang) (not (treesit-ready-p lang t)))
                                      treesit-auto-langs))
              (prompt (format "The following tree-sitter grammars are/were missing:\n%s\n"
                              (mapconcat 'symbol-name to-install "\n"))))
    ;; TODO QOL - it would be nice if this messaged what was installed or at
    ;; least mentioned that nothing was installed if skipped.
    (with-output-to-temp-buffer "*Treesit-auto install candidates*"
      (princ prompt))
    (when (or (eq treesit-auto-install t) ; Quiet mode is off
              (y-or-n-p "Install missing grammars? "))
      (mapcar 'treesit-install-language-grammar to-install))))

In both cases it calls treesit-install-language-grammar without the optional third argument, outdir.

I don't think it should look at treesit-extra-load-path, as that is a list of directories to be used when looking for a grammar and it would be problematic to decide which to use when installing, but there should definitely be a treesit-auto-install-dir.
I don't want to vendor treesit-auto to make that change locally, so for now I live with the following:

(defvar neo/treesit-default-grammar-dir
  (expand-file-name "~/.local/share/emacs/tree-sitter/"))

(defun neo/treesit--install-with-default-dir (orig-fn lang &optional out-dir)
  (funcall orig-fn
           lang
           (or out-dir neo/treesit-default-grammar-dir)))

(advice-add 'treesit-install-language-grammar
            :around #'neo/treesit--install-with-default-dir)

@renzmann any chance to get a way to specify the output directory? some of us use no-littering to keep their init directory clean. I do that + when developing I point my --init-directory inside a monorepo and I certainly don't want grammars in there.