Process Settings notifications off the posting thread (#58978)

Summary:

`SettingsManager` cleans the entire user-defaults dictionary inline whenever a defaults change notification arrives. A write on the main thread therefore performs unrelated, potentially expensive work before returning.

Put the asynchronous update path behind a default-off runtime gate. With the gate off, preserve synchronous snapshot cleaning and event delivery, every intermediate update, the default module queue, and the existing lifecycle registration.

With the gate on, process notifications on a dedicated serial background method queue. Coalesce pending notifications to the latest defaults state, while allowing a notification during a snapshot to schedule a trailing update. Keep JavaScript mutations on the same queue and suppress their notifications at posting time. Drop queued work after invalidation without blocking teardown or retaining the module.

The `settingsUpdated` event name and full JSON-cleaned payload remain unchanged. Enabled-mode rapid external changes may be reported as one latest-state update rather than separate intermediate transitions. Synchronous constants export is unchanged.

Declare the Settings pod's feature-flags dependency so dynamic-framework builds can link the gate.

Changelog:
[iOS][Fixed] - Add an opt-in asynchronous Settings update path to avoid blocking user-defaults writers

Differential Revision: D124504338

Author: Abbondanzo

packages/react-native/Libraries/Settings/RCTSettingsManager.mm

@@ -11,16 +11,24 @@
 #import <React/RCTBridge.h>
 #import <React/RCTConvert.h>
 #import <React/RCTEventDispatcherProtocol.h>
+#import <React/RCTInvalidating.h>
 #import <React/RCTUtils.h>
 
+#include <react/featureflags/ReactNativeFeatureFlags.h>
+#include <atomic>
+
 #import "RCTSettingsPlugins.h"
 
-@interface RCTSettingsManager () <NativeSettingsManagerSpec>
+@interface RCTSettingsManager () <NativeSettingsManagerSpec, RCTInvalidating>
 @end
 
 @implementation RCTSettingsManager {
-  BOOL _ignoringUpdates;
+  std::atomic<bool> _ignoringUpdates;
+  std::atomic<bool> _updateScheduled;
+  std::atomic<bool> _invalidated;
+  bool _useAsyncUpdates;
   NSUserDefaults *_defaults;
+  dispatch_queue_t _methodQueue;
 }
 
 @synthesize moduleRegistry = _moduleRegistry;
@@ -40,7 +48,14 @@ - (instancetype)init
 - (instancetype)initWithUserDefaults:(NSUserDefaults *)defaults
 {
   if ((self = [super init]) != nullptr) {
+    _ignoringUpdates = false;
+    _updateScheduled = false;
+    _invalidated = false;
     _defaults = defaults;
+    _useAsyncUpdates = facebook::react::ReactNativeFeatureFlags::enableAsyncSettingsManagerUpdatesIOS();
+    if (_useAsyncUpdates) {
+      _methodQueue = dispatch_queue_create("com.facebook.react.SettingsManager", DISPATCH_QUEUE_SERIAL);
+    }
 
     [[NSNotificationCenter defaultCenter] addObserver:self
                                              selector:@selector(userDefaultsDidChange:)
@@ -61,18 +76,71 @@ - (instancetype)initWithUserDefaults:(NSUserDefaults *)defaults
       {.settings = RCTJSONClean([_defaults dictionaryRepresentation])});
 }
 
+- (dispatch_queue_t)methodQueue
+{
+  return _methodQueue;
+}
+
+- (BOOL)respondsToSelector:(SEL)selector
+{
+  if (selector == @selector(invalidate) && !_useAsyncUpdates) {
+    return NO;
+  }
+  return [super respondsToSelector:selector];
+}
+
+- (void)invalidate
+{
+  if (!_useAsyncUpdates) {
+    return;
+  }
+  _invalidated = true;
+  [[NSNotificationCenter defaultCenter] removeObserver:self name:NSUserDefaultsDidChangeNotification object:_defaults];
+}
+
 - (void)userDefaultsDidChange:(NSNotification *)note
 {
   if (_ignoringUpdates) {
     return;
   }
 
+  if (!_useAsyncUpdates) {
+    NSDictionary *settings = RCTJSONClean([_defaults dictionaryRepresentation]);
+#pragma clang diagnostic push
+#pragma clang diagnostic ignored "-Wdeprecated-declarations"
+    [[_moduleRegistry moduleForName:"EventDispatcher"] sendDeviceEventWithName:@"settingsUpdated" body:settings];
+#pragma clang diagnostic pop
+    return;
+  }
+
+  if (_invalidated || _updateScheduled.exchange(true)) {
+    return;
+  }
+
+  __weak RCTSettingsManager *weakSelf = self;
+  dispatch_async(_methodQueue, ^{
+    RCTSettingsManager *strongSelf = weakSelf;
+    if (strongSelf == nil) {
+      return;
+    }
+
+    // Clear before reading so a notification during the snapshot schedules a trailing update.
+    strongSelf->_updateScheduled = false;
+    if (strongSelf->_invalidated) {
+      return;
+    }
+
+    NSDictionary *settings = RCTJSONClean([strongSelf->_defaults dictionaryRepresentation]);
+    if (strongSelf->_invalidated) {
+      return;
+    }
+
 #pragma clang diagnostic push
 #pragma clang diagnostic ignored "-Wdeprecated-declarations"
-  [[_moduleRegistry moduleForName:"EventDispatcher"]
-      sendDeviceEventWithName:@"settingsUpdated"
-                         body:RCTJSONClean([_defaults dictionaryRepresentation])];
+    [[strongSelf->_moduleRegistry moduleForName:"EventDispatcher"] sendDeviceEventWithName:@"settingsUpdated"
+                                                                                      body:settings];
 #pragma clang diagnostic pop
+  });
 }
 
 /**

packages/react-native/Libraries/Settings/React-RCTSettings.podspec

@@ -44,6 +44,7 @@ Pod::Spec.new do |s|
   s.dependency "React-jsi"
   s.dependency "React-Core/RCTSettingsHeaders"
 
+  add_dependency(s, "React-featureflags")
   add_dependency(s, "React-RCTFBReactNativeSpec")
   add_dependency(s, "ReactCommon", :subspec => "turbomodule/core", :additional_framework_paths => ["react/nativemodule/core"])
   add_dependency(s, "React-NativeModulesApple", :additional_framework_paths => ["build/generated/ios"])