qbpm/flake.nix at main · pvsr/qbpm · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
{
  description = "A profile manager for qutebrowser";

  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  inputs.pyproject-nix.url = "github:nix-community/pyproject.nix";
  inputs.pyproject-nix.inputs.nixpkgs.follows = "nixpkgs";

  outputs =
    {
      self,
      nixpkgs,
      pyproject-nix,
    }:
    let
      pyproject = pyproject-nix.lib.project.loadPyproject { projectRoot = ./.; };
      pyprojectPackage =
        python: args:
        python.pkgs.buildPythonApplication (
          args // pyproject.renderers.buildPythonPackage { inherit python; }
        );
      pyprojectEnv =
        python: extraPackages:
        python.withPackages (pyproject.renderers.withPackages { inherit python extraPackages; });
      forAllSystems =
        mkOutputs:
        nixpkgs.lib.genAttrs [
          "aarch64-linux"
          "aarch64-darwin"
          "x86_64-darwin"
          "x86_64-linux"
        ] (system: mkOutputs nixpkgs.legacyPackages.${system});
    in
    {
      packages = forAllSystems (pkgs: {
        qbpm = pyprojectPackage pkgs.python3 {
          nativeBuildInputs = [
            pkgs.scdoc
            pkgs.installShellFiles
          ];
          nativeCheckInputs = [ pkgs.python3.pkgs.pytestCheckHook ];
          postInstallCheck = ''
            $out/bin/qbpm --help >/dev/null
            export HOME=$(mktemp -d)
            mkdir -p ~/.config/qutebrowser
            touch ~/.config/qutebrowser/config.py
            $out/bin/qbpm new profile
            $out/bin/qbpm list | grep profile
          '';
          postInstall = ''
            _QBPM_COMPLETE=bash_source $out/bin/qbpm > completions/qbpm.bash
            _QBPM_COMPLETE=zsh_source $out/bin/qbpm > completions/qbpm.zsh
            installShellCompletion completions/qbpm.{bash,zsh,fish}
            scdoc < qbpm.1.scd > qbpm.1
            installManPage qbpm.1
          '';

          meta = {
            homepage = "https://github.com/pvsr/qbpm";
            changelog = "https://github.com/pvsr/qbpm/blob/main/CHANGELOG.md";
            description = "A profile manager for qutebrowser";
            license = pkgs.lib.licenses.gpl3Plus;
          };
        };
        default = self.packages.${pkgs.system}.qbpm;
      });

      apps = forAllSystems (pkgs: {
        qbpm = {
          type = "app";
          program = pkgs.lib.getExe self.packages.${pkgs.system}.qbpm;
        };
        default = self.apps.${pkgs.system}.qbpm;
      });

      checks = forAllSystems (pkgs: self.packages.${pkgs.system});

      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = [
            pkgs.ruff
            (pyprojectEnv pkgs.python3 (ps: [
              ps.flit
              ps.pytest
              ps.pytest-cov
              ps.mypy
              ps.pylsp-mypy
            ]))
          ];
        };
      });

      formatter = forAllSystems (
        pkgs:
        pkgs.nixfmt-tree.override {
          runtimeInputs = [ pkgs.ruff ];
          settings = {
            tree-root-file = "flake.nix";
            formatter.ruff = {
              command = "ruff";
              options = [ "format" ];
              includes = [ "*.py" ];
            };
          };
        }
      );
    };
}