otelite/flake.nix at main · planetf1/otelite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
{
  description = "otelite - lightweight OpenTelemetry receiver and dashboard";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    nix-darwin = {
      url = "github:LnL7/nix-darwin";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "aarch64-darwin"
      ];

      flake =
        let
          nixosModule = import ./nix/nixos-module.nix;
          darwinModule = import ./nix/darwin-module.nix;
        in
        {
          nixosModules = {
            default = nixosModule;
            otelite = nixosModule;
          };
          darwinModules = {
            default = darwinModule;
            otelite = darwinModule;
          };
        };

      perSystem =
        { system, ... }:
        let
          pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ inputs.rust-overlay.overlays.default ];
          };
          lib = pkgs.lib;
          rustToolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
          otelite = pkgs.callPackage ./nix/package.nix { };
          oteliteWorkspace = pkgs.callPackage ./nix/package.nix { workspaceCheck = true; };
          packageOutputs = {
            inherit otelite;
            default = otelite;
          };
          appOutputs = {
            otelite = {
              type = "app";
              program = pkgs.lib.getExe otelite;
              meta.description = "run otelite";
            };
            default = {
              type = "app";
              program = pkgs.lib.getExe otelite;
              meta.description = "run otelite";
            };
          };
          checkOutputs = import ./nix/checks {
            inherit
              inputs
              system
              pkgs
              lib
              otelite
              oteliteWorkspace
              ;
          };
        in
        {
          packages = packageOutputs;

          apps = appOutputs;

          checks = checkOutputs;

          formatter = pkgs.nixfmt-tree;

          devShells.default = pkgs.mkShell {
            packages = [
              rustToolchain
              pkgs.nixfmt-tree
              pkgs.pkg-config
            ];
            buildInputs = [ pkgs.openssl ];
          };
        };
    };
}