SolarSystem/SolarSystem.pde at main · paeddym/SolarSystem · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
import processing.sound.*;

static final float G = 0.1; // Real gravity constant: 6.6743e-11;

ArrayList<Planet> planets = new ArrayList<Planet>();
int planetCount = 9;
boolean paused = false;
boolean muted = false;
boolean trails = false;
boolean tooltipExpanded = false;
String tooltip = "[H]elp";
int randomSeed = (int)random(1, 1000);
int shorterScreenEdgeLength;
SoundFile sound;
SupernovaStage supernovaTooltip = SupernovaStage.STABLE;

void setup() {
  // size(1000, 1000);
  fullScreen();
  noStroke();
  frameRate(60);
  background(0);
  shorterScreenEdgeLength = min(width, height);

  Star sun = new Star(new PVector(width/2, height/2), shorterScreenEdgeLength / 15, 1000 / G, color(200, 150, 0));
  planets.add(sun);

  for (int i = 1; i <= planetCount; i++) {
    float sizeAndMass = random(5, 15);
    PVector location = PVector.random2D();
    location.mult(i * shorterScreenEdgeLength / (planetCount * 2));
    location.add(sun.location);
    Planet newPlanet = new Planet(location, sizeAndMass, new PVector(0, 0), sizeAndMass, color(random(0, 255), random(0, 255), random(0, 255)), random(1) < map(i, 1, planetCount, 0.2, 0.9));
    newPlanet.velocity = getInitialOrbitalVelocity(sun, newPlanet);
    if (newPlanet.hasMoon) {
      Moon moon = newPlanet.createMoon();
      planets.add(moon);
    }
    planets.add(newPlanet);
  }

  sound = new SoundFile(this, "galaxyMap.mp3");
  sound.play();
  sound.loop();
  sound.amp(0.5);
}

void draw() {
  randomSeed(randomSeed);
  if (!trails) {
    background(0);
    fill(255);

    for (int i = 0; i < (width * height / 4000); i++) {
      circle(random(0, width), random(0, height), random(1, 2));
    }
    tooltip = tooltipExpanded ? "[P]ause, [R]eset, Toggle [M]ute, Toggle [T]rails, Toggle [H]elp, [+][-] Simulation Speed: " + round(frameRate/6)/10.0 + ", [S]tart Supernova - Current Stage: " + supernovaTooltip  : "[H]elp";
    text(tooltip, 20, height-20);
  }

  for (Planet planet : planets) {
    if (planet.removed) continue;

    planet.update(planets);
    planet.move();
    planet.drawPlanet();
    planet.checkCollisions(planets);

    if (planet instanceof Star) {
      Star star = (Star)planet;
      if (star.supernovaStarted) star.handleSupernova();
    }
  }
  planets.removeIf(planet -> planet.removed);

  fill(255);
}

void keyPressed() {
  if (key == CODED) {
    switch(keyCode) {
    case UP:
    case RIGHT:
      if (frameRate <= 60) frameRate(frameRate *= 2);
      break;
    case DOWN:
    case LEFT:
      if (frameRate >= 60) frameRate(frameRate /= 2);
      break;
    }
  } else {
    switch(key) {
    case 'p':
      if (paused) {
        loop();
        sound.play();
        if (!muted) {
          sound.amp(0.5);
        } else {
          sound.amp(0);
        }
      } else {
        noLoop();
        sound.pause();
      }
      paused = !paused;
      break;
    case '+':
      if (frameRate < 120) frameRate(frameRate *= 2);
      break;
    case '-':
      if (frameRate > 30) frameRate(frameRate /= 2);
      break;
    case 'm':
      if (muted) {
        sound.amp(0.5);
      } else {
        sound.amp(0);
      }
      muted = !muted;
      break;
    case 'r':
      planets.clear();
      trails = false;
      sound.stop();
      setup();
      break;
    case 't':
      trails = !trails;
      break;
    case 's':
      Star sun = (Star)planets.get(0);
      if (sun.stage != SupernovaStage.FINAL) sun.startSupernova();
      break;
    case 'h':
      tooltipExpanded = !tooltipExpanded;
      break;
    }
  }
}

void mousePressed() {
  float sizeAndMass = random(5, 15);
  PVector location = new PVector(mouseX, mouseY);
  Planet newPlanet = new Planet(location, sizeAndMass, new PVector(0, 0), sizeAndMass, color(random(0, 255), random(0, 255), random(0, 255)), false);
  planets.add(newPlanet);
}