Merge pull request #10665 from nextcloud/work/launch-crash-fp

fix(file-provider): Prevent concurrent write crash in XPC utils

Author: Rello

src/gui/macOS/fileproviderxpc_mac_utils.mm

@@ -76,9 +76,13 @@
                 qCWarning(lcFileProviderXPCUtils) << "Failed to resolve service for file provider domain: " << error;
             } else if (service == nil) {
                 qCWarning(lcFileProviderXPCUtils) << "Service is nil!";
+            } else if (service.name == nil) {
+                qCWarning(lcFileProviderXPCUtils) << "Service has no name";
             } else {
+                @synchronized (fpServices) {
                 [fpServices addObject:@{service.name: service}];
             }
+            }
 
             dispatch_group_leave(group);
         }];
@@ -106,7 +110,11 @@
             }
 
             qCDebug(lcFileProviderXPCUtils) << "Got user visible url" << url;
+            if (url != nil) {
+                @synchronized (urls) {
             [urls addObject:url];
+                }
+            }
             dispatch_group_leave(group);
         }];
     }
@@ -140,7 +148,11 @@
                                       << url.absoluteString
                                       << "has number of services:"
                                       << services.count;
+            if (services != nil) {
+                @synchronized (fpServices) {
             [fpServices addObject:services];
+                }
+            }
             dispatch_group_leave(group);
         }];
     }
@@ -187,7 +199,9 @@
                     return;
                 }
 
+                @synchronized (connections) {
                 [connections addObject:connection];
+                }
                 dispatch_group_leave(group);
             }];
         }

test/macOS/CMakeLists.txt

@@ -7,3 +7,8 @@
 nextcloud_add_test(FinderSyncBrokerIdentity)
 nextcloud_add_test(SystraySyncControlMacOS)
 nextcloud_add_test(MacSandboxUtility)
+
+if(BUILD_FILE_PROVIDER_MODULE)
+    nextcloud_add_test(FileProviderXPCUtils)
+    set_source_files_properties(testfileproviderxpcutils.cpp PROPERTIES COMPILE_FLAGS "-x objective-c++")
+endif()

test/macOS/testfileproviderxpcutils.cpp

@@ -0,0 +1,76 @@
+/*
+ * SPDX-FileCopyrightText: 2026 Nextcloud GmbH and Nextcloud contributors
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+#include <QtTest>
+
+#include "macOS/fileproviderxpc_mac_utils.h"
+
+#import <FileProvider/FileProvider.h>
+
+@interface TestFileProviderService : NSObject
+@property (nonatomic, copy) NSString *name;
+@end
+
+@implementation TestFileProviderService
+@end
+
+@interface TestFileProviderManager : NSObject
+@property (nonatomic, retain) NSFileProviderService *service;
+@end
+
+@implementation TestFileProviderManager
+
+- (void)getServiceWithName:(NSFileProviderServiceName)serviceName
+             itemIdentifier:(NSFileProviderItemIdentifier)itemIdentifier
+          completionHandler:(void (^)(NSFileProviderService *service, NSError *error))completionHandler
+{
+    dispatch_async(dispatch_get_global_queue(QOS_CLASS_DEFAULT, 0), ^{
+        completionHandler(self.service, nil);
+    });
+}
+
+@end
+
+class TestFileProviderXPCUtils : public QObject
+{
+    Q_OBJECT
+
+private Q_SLOTS:
+    void concurrentServiceLookupsCanBeCollected()
+    {
+        constexpr auto managerCount = 128;
+        NSMutableArray<NSFileProviderManager *> * const managers = NSMutableArray.array;
+
+        for (auto index = 0; index < managerCount; ++index) {
+            const auto service = [TestFileProviderService new];
+            service.name = [NSString stringWithFormat:@"service-%d", index];
+
+            const auto manager = [TestFileProviderManager new];
+            manager.service = (NSFileProviderService *)service;
+            [managers addObject:(NSFileProviderManager *)manager];
+            [service release];
+            [manager release];
+        }
+
+        const auto services = OCC::Mac::FileProviderXPCUtils::getFileProviderServices(managers);
+        QCOMPARE(services.count, managerCount);
+    }
+
+    void serviceWithoutNameIsIgnored()
+    {
+        const auto service = [TestFileProviderService new];
+        const auto manager = [TestFileProviderManager new];
+        manager.service = (NSFileProviderService *)service;
+
+        const auto services = OCC::Mac::FileProviderXPCUtils::getFileProviderServices(@[(NSFileProviderManager *)manager]);
+        QCOMPARE(services.count, 0);
+
+        [service release];
+        [manager release];
+    }
+};
+
+QTEST_APPLESS_MAIN(TestFileProviderXPCUtils)
+#include "testfileproviderxpcutils.moc"