windeployqt fails to deploy plugins in qt5. #51973

Flying-Magnus · 2026-05-26T06:46:59Z

Flying-Magnus
May 26, 2026

I'm a beginner programmer and I'm on an osg-qt project.
I try to use windeployqt to copy qt plugins to bin dir, and it says

Unable to query qmake: CreateProcessW failed: 
ninja: build stopped: subcommand failed.

Is it a bug or am i doing some wrong things?
Help needed.

This is my CMakeLists.txt

cmake_minimum_required (VERSION 4.3)

project ("MyAwesomeProject" VERSION 0.0.0 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)

find_package(Qt5 CONFIG COMPONENTS Widgets Core Gui REQUIRED)
find_package(OpenSceneGraph COMPONENTS osgDB osgViewer osgGA osg osgUtil osgText osgSim osgFX REQUIRED)
if (${CMAKE_BUILD_TYPE} STREQUAL "Debug")
    find_library(OSGQOPENGL_LIB REQUIRED
        NAMES osgQOpenGLd
        PATHS
            ${CMAKE_PREFIX_PATH}/debug/lib
        )
else()
    find_library(OSGQOPENGL_LIB REQUIRED
        NAMES osgQOpenGL
        PATHS
            ${CMAKE_PREFIX_PATH}/lib
        )
endif()

add_executable(main)
target_include_directories(main PRIVATE
    ${CMAKE_SOURCE_DIR}/src
    ${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include
    )
file(GLOB_RECURSE SRC_FILES CONFIGURE_DEPENDS src/*.cpp)
target_sources(main PRIVATE
    ${SRC_FILES})

target_link_libraries(main PRIVATE
    Qt5::Widgets Qt5::Core Qt5::Gui
    ${OPENSCENEGRAPH_LIBRARIES}
    ${OSGQOPENGL_LIB}
    )

if(WIN32)
    set_target_properties(main PROPERTIES
        WIN32_EXECUTABLE "$<CONFIG:Release>"
    )
    find_program(WINDEPLOYQT windeployqt REQUIRED)
    add_custom_command(
        TARGET main POST_BUILD
        COMMAND
            ${WINDEPLOYQT}
            $<TARGET_FILE:main>
            --no-translations
    )
endif()

and vcpkg.json

{
    "dependencies": [
        "osg-qt",
        "qt5-tools"
    ]
}

and CMakePresets.json

{
    "version": 10,
	"configurePresets": [
		{
			"name": "default",
			"hidden": true,
			"description": "基础配置",
			"generator": "Ninja",
			"binaryDir": "${sourceDir}/build/${presetName}",
			"cacheVariables": {
				"CMAKE_CXX_STANDARD": "17",
				"CMAKE_CXX_STANDARD_REQUIRED": "ON",
				"CMAKE_EXPORT_COMPILE_COMMANDS": "ON",
				"CMAKE_TOOLCHAIN_FILE": "$env{VCPKG_ROOT}/scripts/buildsystems/vcpkg.cmake",
				"VCPKG_INSTALLED_DIR": "${sourceDir}/vcpkg_installed"
			}
		},
		{
			"name": "windows",
			"hidden": true,
			"description": "Windows 配置",
			"condition": {
				"type": "equals",
				"lhs": "${hostSystemName}",
				"rhs": "Windows"
			},
			"cacheVariables": {
				"VCPKG_TARGET_TRIPLET": "x64-windows"
			}
		},
		{
			"name": "debug",
			"hidden": true,
			"description": "debug 配置",
			"cacheVariables": {
				"CMAKE_BUILD_TYPE": "Debug"
			}
		},
		{
			"name": "release",
			"hidden": true,
			"description": "release 配置",
			"cacheVariables": {
				"CMAKE_BUILD_TYPE": "Release"
			}
		},
		{
			"name": "windows-debug",
			"displayName": "Windows Debug",
			"description": "Windows平台Debug构建",
			"inherits": ["default","windows","debug"]
		},
		{
			"name": "windows-release",
			"displayName": "Windows Release",
			"description": "Windows平台Release构建",
			"inherits": ["default","windows","release"]
		}
	],
	"buildPresets": [
		{
			"name": "windows-debug",
			"configurePreset": "windows-debug",
			"displayName": "Windows Debug Build"
		},
		{
			"name": "windows-release",
			"configurePreset": "windows-release",
			"displayName": "Windows Release Build"
		}
	]
}

Answered by Flying-Magnus

May 28, 2026

Thanks for your help, Serge Yudin (@yudin-s) .

I search the whole vcpkg_installed directory and find 3 windeployqt.exe respecitvely in vcpkg_installed\x64-windows\tools\qt5-tools\bin, vcpkg_installed\x64-windows\tools\qt5\bin and vcpkg_installed\x64-windows\tools\qt5\debug\bin

The final solution is this:

if(WIN32)
    if(CMAKE_BUILD_TYPE STREQUAL "Debug")
        set(QT5TOOL_PATH ${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/tools/qt5/debug/bin/)
    else()
        set(QT5TOOL_PATH ${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/tools/qt5/bin/)
    endif()

    find_program(WINDEPLOYQT windeployqt 
        NO_DEFAULT_PATH
        PATHS ${QT5TOOL_PATH}
        REQUIRED
    )
    add_custom…

View full answer

Serge Yudin (yudin-s) · 2026-05-26T07:12:44Z

Serge Yudin (yudin-s)
May 26, 2026

This is probably not your C++ code. It is usually a Qt tool lookup problem: the windeployqt executable was found, but that executable cannot start the matching qmake.

With vcpkg/Qt, avoid calling a random windeployqt.exe from PATH. Use the Qt tool target/wrapper when available, or pass the matching qmake explicitly.

A practical CMake shape is:

find_package(Qt5 CONFIG REQUIRED COMPONENTS Widgets Core Gui)

if(WIN32)
  get_target_property(QMAKE_EXE Qt5::qmake IMPORTED_LOCATION)
  get_target_property(WINDEPLOYQT_EXE Qt5::windeployqt IMPORTED_LOCATION)

  add_custom_command(TARGET main POST_BUILD
    COMMAND "${WINDEPLOYQT_EXE}"
            --qmake "${QMAKE_EXE}"
            --no-translations
            "$<TARGET_FILE:main>"
    VERBATIM
  )
endif()

If Qt5::windeployqt is not exported in your setup, first check what CMake actually found:

message(STATUS "windeployqt=${WINDEPLOYQT}")

and on Windows:

where windeployqt
where qmake

The important rule is that windeployqt and qmake must come from the same vcpkg Qt installation/triplet, including Debug vs Release wrappers. If find_program(WINDEPLOYQT windeployqt) picks an executable outside vcpkg_installed/x64-windows/tools/Qt5/bin, it can fail exactly like this.

If this solves it, please mark the comment as the answer so others can find it faster.

3 replies

Flying-Magnus May 26, 2026
Author

I tried your suggestions. But it did not work.
Qt5::windeployqt is not exported.
WINDEPLOYQT is not set unless i try find_program(WINDEPLOYQT windeployqt REQUIRED).
option --qmake <path> is introduced in qt6 and not available in qt5.

Qt5.15 doc windows-deployment
Qt6 doc windows-deployment

I don't edit environment variable PATH to use tools.
I checked that find_program(WINDEPLOYQT windeployqt) and find_program(QMAKE qmake)
WINDEPLOYQT is <myproject_dir>/vcpkg_installed/x64-windows/tools/qt5-tools/bin/windeployqt.exe
QMAKE is <myproject_dir>/vcpkg_installed/x64-windows/tools/qt5-base/bin/qmake.exe

Serge Yudin (yudin-s) May 27, 2026

You are right on both Qt5 points. My --qmake suggestion was Qt6-specific, so ignore that part for Qt5.

For Qt5 with vcpkg, the more likely issue is the split you found:

windeployqt.exe -> vcpkg_installed/x64-windows/tools/qt5-tools/bin
qmake.exe       -> vcpkg_installed/x64-windows/tools/qt5-base/bin

Qt5 windeployqt cannot be told --qmake, so it has to be able to find the matching qmake.exe in its process environment. You do not need to edit the global Windows PATH; set it only for that post-build command:

if(WIN32)
  set(QT5_BASE_TOOLS "${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/tools/qt5-base/bin")
  set(QT5_TOOLS      "${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/tools/qt5-tools/bin")

  find_program(WINDEPLOYQT
    NAMES windeployqt
    PATHS "${QT5_TOOLS}"
    NO_DEFAULT_PATH
    REQUIRED
  )

  find_program(QMAKE
    NAMES qmake
    PATHS "${QT5_BASE_TOOLS}"
    NO_DEFAULT_PATH
    REQUIRED
  )

  add_custom_command(TARGET main POST_BUILD
    COMMAND "${CMAKE_COMMAND}" -E env
            "PATH=${QT5_BASE_TOOLS};${QT5_TOOLS};$ENV{PATH}"
            "${WINDEPLOYQT}"
            --no-translations
            "$<TARGET_FILE:main>"
    VERBATIM
  )
endif()

The QMAKE variable is just a sanity check here; Qt5 windeployqt will discover it through the temporary PATH used for this one command.

If that still fails, print the environment from the same post-build command before running windeployqt:

COMMAND "${CMAKE_COMMAND}" -E env "PATH=${QT5_BASE_TOOLS};${QT5_TOOLS};$ENV{PATH}" where qmake
COMMAND "${CMAKE_COMMAND}" -E env "PATH=${QT5_BASE_TOOLS};${QT5_TOOLS};$ENV{PATH}" where windeployqt

That should confirm whether the build step sees the same Qt5 tool pair you found manually.

Flying-Magnus May 28, 2026
Author

Thanks for your help, Serge Yudin (@yudin-s) .

I search the whole vcpkg_installed directory and find 3 windeployqt.exe respecitvely in vcpkg_installed\x64-windows\tools\qt5-tools\bin, vcpkg_installed\x64-windows\tools\qt5\bin and vcpkg_installed\x64-windows\tools\qt5\debug\bin

The final solution is this:

if(WIN32)
    if(CMAKE_BUILD_TYPE STREQUAL "Debug")
        set(QT5TOOL_PATH ${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/tools/qt5/debug/bin/)
    else()
        set(QT5TOOL_PATH ${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/tools/qt5/bin/)
    endif()

    find_program(WINDEPLOYQT windeployqt 
        NO_DEFAULT_PATH
        PATHS ${QT5TOOL_PATH}
        REQUIRED
    )
    add_custom_command(
        TARGET main POST_BUILD
        COMMAND
            ${WINDEPLOYQT}
            $<TARGET_FILE:main>
            --no-translations
    )
endif()

Answer selected by Flying-Magnus

Navigation Menu

Uh oh!

windeployqt fails to deploy plugins in qt5. #51973

Uh oh!

{{title}}

Uh oh!

Uh oh!

{{editor}}'s edit

{{editor}}'s edit

Uh oh!

Replies: 1 comment 3 replies

Uh oh!

{{title}}

Uh oh!

Uh oh!

{{title}}

Uh oh!

Uh oh!

{{editor}}'s edit

{{editor}}'s edit

Uh oh!

Uh oh!

{{title}}

Uh oh!

Uh oh!

{{title}}

Uh oh!

Uh oh!

{{editor}}'s edit

{{editor}}'s edit

Uh oh!

Select a reply

Uh oh!

Uh oh!

windeployqt fails to deploy plugins in qt5. #51973

Uh oh!

Uh oh!

Flying-Magnus May 26, 2026

Replies: 1 comment · 3 replies

Uh oh!

Serge Yudin (yudin-s) May 26, 2026

Uh oh!

Uh oh!

Flying-Magnus May 26, 2026 Author

Uh oh!

Serge Yudin (yudin-s) May 27, 2026

Uh oh!

Uh oh!

Flying-Magnus May 28, 2026 Author

Flying-Magnus
May 26, 2026

Replies: 1 comment 3 replies

Serge Yudin (yudin-s)
May 26, 2026

Flying-Magnus May 26, 2026
Author

Flying-Magnus May 28, 2026
Author