How to use vcpkg in manifest mode with emscripten and compile dependency with emscripten pthread support

[OnBings (onbings)]

Hi,
I have an application which uses an external lib dependency which uses c++ threads (for example spdlog). If i target my desktop all is ok. If i target emscripten it does not work because the dependency spdlog is compiled without thread support via the wasm32-emscripten triplet and the VCPKG_CHAINLOAD_TOOLCHAIN_FILE=C:/pro/emsdk/upstream/emscripten/cmake/Modules/Platform/emscripten.cmake toolchain.

To activate the thread support in emscripten you need to pass the "-s NO_DISABLE_EXCEPTION_CATCHING -s ALLOW_MEMORY_GROWTH -s TOTAL_STACK=8388608" flags to the compilation chain but this is not made when vcpkd compile its dependencies. I don't want to create a specific port file for all the external lib I use to include this emscripten pthread support.
Is there a way to tell vcpkg to add specific options when it compiles an external lib. I try to put them in another priplet or in the emscripten.cmake toolchain without success

In short when i compile my app, i use the following command:
{
"directory": "C:/bld/bofstd-web",
"command": "C:\pro\emsdk\upstream\emscripten\em++.bat -DCRT_NONSTDC_NO_DEPRECATE -DCRT_SECURE_NO_WARNINGS -DIXML_STATIC_LIB -DONLY_C_LOCALE=0 -DSPDLOG_COMPILED_LIB -DSPDLOG_FMT_EXTERNAL -DUSE_OS_TZDB=1 -DWINSOCK_DEPRECATED_NO_WARNINGS -Dbofstd_EXPORTS=1 -IC:/pro/github/bofstd/lib/include -IC:/pro/github/bofstd/lib/third/cpp-linenoise-master -IC:/pro/github/bofstd/lib/third/AsyncMulticastDelegate/include -IC:/pro/github/bofstd/lib/third/ixml/inc -IC:/pro/github/bofstd/lib/third/ixml/src/inc -IC:/bld/bofstd-web/lib -IC:/pro/emsdk/upstream/emscripten/cache/sysroot -isystem C:/bld/bofstd-web/vcpkg_installed/wasm32-emscripten/include -pthread -s NO_DISABLE_EXCEPTION_CATCHING -s ALLOW_MEMORY_GROWTH -s TOTAL_STACK=8388608 -g -std=c++17 -fvisibility=hidden -o lib\CMakeFiles\bofstd.dir\src\bofstd.cpp.o -c C:\pro\github\bofstd\lib\src\bofstd.cpp",
"file": "C:\pro\github\bofstd\lib\src\bofstd.cpp",
"output": "lib\CMakeFiles\bofstd.dir\src\bofstd.cpp.o"
}
but when vcpkg compile its dependency it uses c++ flags which comes from its port file...

Thank you for your help and time

[Kai Pastor (dg0yt)]

To activate the thread support in emscripten you need to pass the "-s NO_DISABLE_EXCEPTION_CATCHING -s ALLOW_MEMORY_GROWTH -s TOTAL_STACK=8388608" flags to the compilation chain

Actually it should need -pthread:
https://emscripten.org/docs/porting/pthreads.html#compiling-with-pthreads-enabled

I found that find_package(Threads) doesn't add it to the properties of Threads::Threads for Emscripten because it thinks that there is pthread support in the C lib.

To add it to the triplet-wide compile flags, you would string-append to VCPKG_C_FLAGS and VCPKG_CXX_FLAGS in the (probably custom or overlay) triplet file. But I didn't test this.

[Matthias Kuhn (m-kuhn)]

Unfortuantely, this doesn't work.

the VCPKG_..._FLAGS are handled in the toolchains from scripts/toolchains but wasm uses a toolchain maintained by emscripten

vcpkg/triplets/community/wasm32-emscripten.cmake

Line 24 in 52f93a6

set(VCPKG_CHAINLOAD_TOOLCHAIN_FILE "${EMSCRIPTEN_ROOT}/cmake/Modules/Platform/Emscripten.cmake")

I have added a local overlay triplet and passed the path to EMSCRIPTEN_ROOT via an environment variable

set(VCPKG_CHAINLOAD_TOOLCHAIN_FILE "${CMAKE_CURRENT_LIST_DIR}/toolchains/wasm.cmake")
set(ENV{EMSCRIPTEN_ROOT} "${EMSCRIPTEN_ROOT}")

set(EXTRA_FLAGS "-pthread -fwasm-exceptions -msimd128")

set(VCPKG_C_FLAGS "${EXTRA_FLAGS}")
set(VCPKG_CXX_FLAGS "${EXTRA_FLAGS}")

where toolchains/wasm.cmake looks like this:

if(NOT _VCPKG_WASM_TOOLCHAIN)
    set(_VCPKG_WASM_TOOLCHAIN 1)

    string(APPEND CMAKE_C_FLAGS_INIT " -fPIC ${VCPKG_C_FLAGS} ")
    string(APPEND CMAKE_CXX_FLAGS_INIT " -fPIC ${VCPKG_CXX_FLAGS} ")
    string(APPEND CMAKE_C_FLAGS_DEBUG_INIT " ${VCPKG_C_FLAGS_DEBUG} ")
    string(APPEND CMAKE_CXX_FLAGS_DEBUG_INIT " ${VCPKG_CXX_FLAGS_DEBUG} ")
    string(APPEND CMAKE_C_FLAGS_RELEASE_INIT " ${VCPKG_C_FLAGS_RELEASE} ")
    string(APPEND CMAKE_CXX_FLAGS_RELEASE_INIT " ${VCPKG_CXX_FLAGS_RELEASE} ")

    string(APPEND CMAKE_MODULE_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
    string(APPEND CMAKE_SHARED_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
    string(APPEND CMAKE_EXE_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
    string(APPEND CMAKE_MODULE_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
    string(APPEND CMAKE_SHARED_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
    string(APPEND CMAKE_EXE_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
    string(APPEND CMAKE_MODULE_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
    string(APPEND CMAKE_SHARED_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
    string(APPEND CMAKE_EXE_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")

    include("$ENV{EMSCRIPTEN_ROOT}/cmake/Modules/Platform/Emscripten.cmake")
endif()

[Kai Pastor (dg0yt)]

Indeed, VCPKG_C(XX)_FLAGS is specific to the chainloaded vcpkg toolchains. For consistent behavior, it seems necessary to always wrap SDK toolchain files.

[Matthias Kuhn (m-kuhn)]

I am still looking for a solution without environment variables, not sure if that's possible.