dotfiles/flake.nix at main · malbertzard/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
{
  description = "Nix Dotsfiles with flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixos-hardware.url = "github:NixOS/nixos-hardware/master";

    nixpkgs-stable.url = "github:NixOS/nixpkgs/nixos-24.11";
    home-manager-stable = {
      url = "github:nix-community/home-manager/release-24.11";
      inputs.nixpkgs.follows = "nixpkgs-stable";
    };
  };

  outputs =
    {
      self,
      ...
    }@inputs:

    let
      hosts = import ./hosts.nix;

      mkHomeConfigurations =
        {
          host,
          nixpkgs,
          home-manager,
          modules ? [ ],
        }:
        home-manager.lib.homeManagerConfiguration {
          pkgs = import nixpkgs {
            system = host.arch;
            config = {
              allowUnfree = true;
            };
          };

          extraSpecialArgs = {
            inherit host;
          };

          modules = [
            ./hosts/${host.dir}/home.nix
            ./overlays
          ] ++ modules;
        };

      mkNixOSConfigurations =
        {
          host,
          nixpkgs,
          nixos-hardware,
          home-manager,
          modules ? [ ],
          overlays ? [ ],
        }:
        nixpkgs.lib.nixosSystem {
          system = host.arch;
          specialArgs = {
            inherit host;
          };
          modules = [
            ./hosts/${host.dir}/configuration.nix
            { nixpkgs.overlays = overlays; }
            ./overlays
            home-manager.nixosModules.home-manager
            {
              home-manager.extraSpecialArgs = {
                inherit host;
              };
              home-manager.useGlobalPkgs = true;
              home-manager.users."${host.user}" = import ./hosts/${host.dir}/home.nix;
            }
          ] ++ modules;
        };

    in

    {
      homeConfigurations."${hosts.debian.user}@${hosts.debian.hostname}" = mkHomeConfigurations {
        host = hosts.debian;
        nixpkgs = inputs.nixpkgs;
        home-manager = inputs.home-manager;
      };

      nixosConfigurations."${hosts.nixos.hostname}" = mkNixOSConfigurations {
        host = hosts.nixos;
        nixpkgs = inputs.nixpkgs;
        nixos-hardware = inputs.nixos-hardware.nixosModules."${hosts.nixos.hardware}";
        home-manager = inputs.home-manager;
      };
    };
}