kubectl completion fish - label support required

[rforberger]

What would you like to be added:

When running fish shell, currently completions do not support label support yet.

For example:

kubectl get pods -l app= # tab tab

I need a feature, where you can press tab tab when doing for example get pods or other commands and label suggestions are automatically completed. I don't know if this is already implemented.

Running

kubectl completion fish as far as I understand does not yet support it.

Can it be implemented?

Why is this needed:

Comfortable function, time saving.

[kubernetes-prow]

This issue is currently awaiting triage.

SIG CLI takes a lead on issue triage for this repo, but any Kubernetes member can accept issues by applying the triage/accepted label.

The triage/accepted label can be added by org members by writing /triage accepted in a comment.

Details

Instructions for interacting with me using PR comments are available here. If you have questions or suggestions related to my behavior, please file an issue against the kubernetes-sigs/prow repository.

[rforberger]

This is a version, that automates the values completion, but not the key completion yet. I want a version, which both automates key completion and value completion. No AI can do it yet.

Here is the example:

function __kubectl_ns_flag --description 'Extract -n/--namespace value from the current command line, if present'
    set -l tokens (commandline -opc)
    for i in (seq (count $tokens))
        switch $tokens[$i]
            case -n --namespace
                if test (math $i + 1) -le (count $tokens)
                    echo $tokens[(math $i + 1)]
                    return
                end
        end
    end
end
 
function __kubectl_selector_context --description 'True when completing the value of -l/--selector'
    set -l tokens (commandline -opc)
    set -l last $tokens[-1]
    contains -- $last -l --selector
end
 
function __kubectl_label_keys --description 'All label keys seen on pods in scope'
    set -l ns (__kubectl_ns_flag)
    set -l args get pods -o json
    if test -n "$ns"
        set args $args -n $ns
    end
    kubectl $args 2>/dev/null | jq -r '.items[].metadata.labels // {} | keys[]' 2>/dev/null | sort -u
end
 
function __kubectl_label_values --description 'All values seen for a given label key'
    set -l key $argv[1]
    set -l ns (__kubectl_ns_flag)
    set -l args get pods -o json
    if test -n "$ns"
        set args $args -n $ns
    end
    kubectl $args 2>/dev/null | jq -r --arg k "$key" '.items[].metadata.labels[$k] // empty' 2>/dev/null | sort -u
end
 
function __kubectl_complete_selector --description 'Complete key or key=value for -l/--selector, comma-separated aware'
    set -l cur (commandline -ct)
 
    # Support multi-label selectors like app=foo,tier=<TAB>:
    # keep everything up to the last comma as a literal prefix.
    set -l prefix ''
    set -l fragment $cur
    if string match -q '*,*' -- $cur
        set prefix (string replace -r '[^,]*$' '' -- $cur)
        set fragment (string replace -r '^.*,' '' -- $cur)
    end
 
    if string match -q '*=*' -- $fragment
        set -l key (string split -m1 '=' -- $fragment)[1]
        for v in (__kubectl_label_values $key)
            echo "$prefix$key=$v"
        end
    else
        for k in (__kubectl_label_keys)
            echo "$prefix$k="
        end
    end
end
 
complete -c kubectl -n __kubectl_selector_context -f -a '(__kubectl_complete_selector)'