dotfiles/flake.nix at master · khaykingleb/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
{
  description = "Declarative system configuration and package management for macOS";

  inputs = {
    # Private configuration with sensitive data
    private-config = {
      url = "git+ssh://git@github.com/khaykingleb/dotfiles-private.git";
      flake = false;
    };

    # Main package supplier
    nixpkgs = {
      type = "github";
      owner = "NixOS";
      repo = "nixpkgs";
      ref = "nixpkgs-unstable";
    };

    # Support for MacOS specific features
    # https://github.com/LnL7/nix-darwin
    nix-darwin = {
      type = "github";
      owner = "lnl7";
      repo = "nix-darwin";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Manage userspace with nix
    # https://github.com/nix-community/home-manager
    home-manager = {
      type = "github";
      owner = "nix-community";
      repo = "home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Integrates homebrew with nix-darwin
    # https://github.com/zhaofengli/nix-homebrew
    nix-homebrew = {
      type = "github";
      owner = "zhaofengli";
      repo = "nix-homebrew";
    };

    homebrew-bundle = {
      type = "github";
      owner = "homebrew";
      repo = "homebrew-bundle";
      flake = false;
    };

    homebrew-core = {
      type = "github";
      owner = "homebrew";
      repo = "homebrew-core";
      flake = false;
    };

    homebrew-cask = {
      type = "github";
      owner = "homebrew";
      repo = "homebrew-cask";
      flake = false;
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      nix-darwin,
      home-manager,
      nix-homebrew,
      homebrew-bundle,
      homebrew-core,
      homebrew-cask,
      ...
    }@inputs:
    let
      darwinArch = {
        macbook-pro-m1 = {
          system = "aarch64-darwin";
          user = "khaykingleb";
        };
        macbook-pro-m4 = {
          system = "aarch64-darwin";
          user = "khaykingleb";
        };
        macbook-pro-m4-together = {
          system = "aarch64-darwin";
          user = "gkhaykin";
        };
      };
      systems = [
        "aarch64-darwin"
        "x86_64-linux"
      ];
      mkDarwin =
        name:
        { system, user }:
        nix-darwin.lib.darwinSystem {
          inherit system;
          specialArgs = {
            inherit inputs user;
            hostName = name;
          };
          modules = [
            home-manager.darwinModules.home-manager # NOTE: integrates home-manager with nix-darwin
            nix-homebrew.darwinModules.nix-homebrew # NOTE: integrates homebrew with nix-darwin
            {
              nix-homebrew = {
                inherit user;
                enable = true;
                taps = {
                  "homebrew/homebrew-core" = homebrew-core;
                  "homebrew/homebrew-cask" = homebrew-cask;
                  "homebrew/homebrew-bundle" = homebrew-bundle;
                };
                mutableTaps = false;
                autoMigrate = true;
              };
            }
            ./nix/hosts/${name}
          ];
        };
      forAllSystems = nixpkgs.lib.genAttrs systems;
      mkDevShell =
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default =
            with pkgs;
            mkShell {
              buildInputs = [
                git
                pre-commit
                openssl
                gnupg
                gnutar
                xz
                zlib
                ncurses
                bzip2
                libffi
                sqlite
              ];
            };
        };
    in
    {
      devShells = forAllSystems mkDevShell;
      darwinConfigurations = builtins.mapAttrs mkDarwin darwinArch;
    };
}