Matrix-M4-OpenRGB/OpenRgbMatrixPortalPlugin.pro at main · ikeroy/Matrix-M4-OpenRGB · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
QT += core gui widgets

TEMPLATE = lib
CONFIG += plugin c++17 silent
TARGET = OpenRgbMatrixPortalPlugin

GIT_COMMIT_ID   = $$system(git log -n 1 --pretty=format:"%H")
isEmpty(GIT_COMMIT_ID) {
      GIT_COMMIT_ID = unknown
}
DEFINES += GIT_COMMIT_ID=\\\"$$GIT_COMMIT_ID\\\"

isEmpty(OPENRGB_DIR) {
    OPENRGB_DIR = $$(OPENRGB_DIR)
}
isEmpty(OPENRGB_DIR) {
    OPENRGB_DIR = OpenRGB/
}

INCLUDEPATH += \
    $$OPENRGB_DIR \
    $$OPENRGB_DIR/RGBController \
    $$OPENRGB_DIR/i2c_smbus

HEADERS += \
    $$OPENRGB_DIR/OpenRGBPluginInterface.h \
    $$OPENRGB_DIR/ResourceManagerInterface.h \
    $$OPENRGB_DIR/RGBController/RGBController.h \
    src/MatrixPortalRgbController.h \
    src/OpenRgbMatrixPortalPlugin.h \
    src/SerialFrameWriter.h

SOURCES += \
    $$OPENRGB_DIR/RGBController/RGBController.cpp \
    src/MatrixPortalRgbController.cpp \
    src/OpenRgbMatrixPortalPlugin.cpp \
    src/SerialFrameWriter.cpp


RESOURCES += \
    resources.qrc

unix:LIBS += -lpthread