ndiprint/CMakeLists.txt at master · dkprog/ndiprint · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
cmake_minimum_required(VERSION 3.10)

project(ndiprint VERSION 1.0.0)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED True)
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -O0")
set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -O2")
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O2")

add_executable(
  ndiprint
  src/main.cpp
  src/frame.cpp
  src/buffer.cpp
)

target_include_directories(
  ndiprint PRIVATE
  ${CMAKE_SOURCE_DIR}/include
)

target_link_directories(
  ndiprint PRIVATE
  ${CMAKE_SOURCE_DIR}/lib
)

target_compile_definitions(
  ndiprint
  PRIVATE
  PROJECT_NAME="${PROJECT_NAME}"
  $<$<CONFIG:Debug>:DEBUG>
)

target_link_libraries(
  ndiprint PUBLIC
  "-lndi"
)

set_target_properties(ndiprint PROPERTIES
  INSTALL_RPATH "\$ORIGIN/../lib"
  BUILD_RPATH "${CMAKE_SOURCE_DIR}/lib"
)

install(TARGETS ndiprint
  RUNTIME DESTINATION bin
)

install(DIRECTORY ${CMAKE_SOURCE_DIR}/lib/
  DESTINATION lib
  FILES_MATCHING
    PATTERN "*.so*"
)

# --- CPack DEB ---
set(CPACK_PACKAGING_INSTALL_PREFIX "/opt/ndiprint")
set(CPACK_GENERATOR "DEB")
set(CPACK_PACKAGE_NAME "ndiprint")
set(CPACK_PACKAGE_VERSION "${PROJECT_VERSION}")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "Daniel Koch <daniel@dkprog.com>")
set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "amd64")
set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.39), libstdc++6 (>= 13)")
set(CPACK_DEBIAN_PACKAGE_DESCRIPTION "NDI print utility")
set(CPACK_DEBIAN_PACKAGE_SECTION "video")
set(CPACK_DEBIAN_FILE_NAME "ndiprint_${PROJECT_VERSION}_amd64.deb")
set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA
  "${CMAKE_SOURCE_DIR}/packaging/postinst;${CMAKE_SOURCE_DIR}/packaging/prerm")
include(CPack)