How to overlay packages over nixpkgs?

[nikolai-in]

How can I overlay my packages defined in a ../pkgs directory over the nixpkgs globally?
I found an example of how to include packages from a directory in a flake output (templates/flake-parts-modules), but can't figure out how to make them available inside the flake. Following instructions from pkgs-by-name-for-flake-parts on making an overlay doesn't seem to work. I've been stuck on this for some time and would appreciate any help.

PS Thank you for this amazing project

[drupol]

Hello,

1. Please share a repository where I can see what you're trying to do
2. Have you checked the README file of drupol/pkgs-by-name-for-flake-parts ?
3. Perhaps have a look at this project, it might help: https://github.com/drupol/my-own-nixpkgs

Thanks!

[nikolai-in]

Thank you! Figured it out, checked out your configuration and got it working with

{
  den,
  inputs,
  withSystem,
  ...
}:
{
  flake-file.inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
    nixpkgs-master.url = "github:NixOS/nixpkgs/master";
    nixpkgs-unstable.url = "github:nixos/nixpkgs?ref=nixos-unstable";

    pkgs-by-name.url = "github:drupol/pkgs-by-name-for-flake-parts";

    home-manager = {
      url = "github:nix-community/home-manager/release-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  imports = [
    inputs.flake-file.flakeModules.default
    inputs.pkgs-by-name.flakeModule
  ];

  flake = {
    overlays.default = _final: prev: {
      local = withSystem prev.stdenv.hostPlatform.system ({ config, ... }: config.packages);
    };
  };

  perSystem =
    { system, ... }:
    {
      _module.args.pkgs = import inputs.nixpkgs {
        inherit system;

        overlays = [
          (final: _prev: {
            master = import inputs.nixpkgs-master {
              inherit (final) config;
              inherit system;
            };
          })
          (final: _prev: {
            unstable = import inputs.nixpkgs-unstable {
              inherit (final) config;
              inherit system;
            };
          })
        ];
      };

      pkgsDirectory = ../pkgs;
    };

  den.default.nixos = {
    nixpkgs.overlays = [
      inputs.self.overlays.default
    ];
  };
}

Now I can use my packages anywhere with just pkgs.local. Still can't quite figure out where .local came from . . .
Feels like I'm just copying and pasting stuff until it works. It's been half a year, but nix still feels strange to me.

[drupol]

Now I can use my packages anywhere with just pkgs.local. Still can't quite figure out where .local came from . . .

From here:

  flake = {
    overlays.default = _final: prev: {
      local = withSystem prev.stdenv.hostPlatform.system ({ config, ... }: config.packages);
    };
  };

local is an arbitrary name, you could name it foobar if you prefer, then access your packages with pkgs.foobar.<package>.

Don't forget that you can also access your packages through config: config.packages.<package>.

Hope it helps!