nix-configs/flake.nix at main · bebert64/nix-configs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
{
  description = "NixOS and HomeManager configurations";

  nixConfig = {
    # Increase download buffer size to avoid warnings when downloading large files
    # 256 MB (268435456 bytes) should be sufficient for most builds
    download-buffer-size = 268435456;
  };

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable"; # pinned to 2.1.87, revert to "github:nixos/nixpkgs/nixos-unstable" once fixed
    by-db = {
      url = "git+ssh://git@github.com/bebert64/perso";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    home-manager = {
      url = "github:nix-community/home-manager/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    stockly-computers = {
      url = "git+ssh://git@github.com/Stockly/Computers.git";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    vscode-server = {
      url = "github:nix-community/nixos-vscode-server";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      by-db,
      home-manager,
      nixpkgs-unstable,
      nixpkgs,
      sops-nix,
      stockly-computers,
      vscode-server,
      ...
    }:
    let
      pkgsUnstable = import nixpkgs-unstable {
        system = "x86_64-linux";
        config.allowUnfree = true;
      };
      mkHost =
        {
          modules,
          extraSpecialArgs ? { },
        }:
        nixpkgs.lib.nixosSystem {
          inherit modules;
          specialArgs = {
            inherit
              home-manager
              nixpkgs
              sops-nix
              ;
          }
          // extraSpecialArgs;
        };
    in
    {
      packages.x86_64-linux.home-manager = home-manager.packages.x86_64-linux.home-manager;

      homeConfigurations.monsters = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages.x86_64-linux;
        modules = [ ./home-manager/monsters.nix ];
        extraSpecialArgs = { inherit pkgsUnstable sops-nix; };
      };

      nixosConfigurations = {
        bureau = mkHost {
          modules = [ ./computers/bureau/configuration.nix ];
          extraSpecialArgs = { inherit by-db pkgsUnstable; };
        };

        raspi4 = mkHost {
          modules = [ ./computers/raspi4/configuration.nix ];
          extraSpecialArgs = { inherit vscode-server; };
        };

        salon = mkHost {
          modules = [ ./computers/salon/configuration.nix ];
          extraSpecialArgs = {
            inherit
              by-db
              pkgsUnstable
              vscode-server
              ;
          };
        };

        stockly-romainc = stockly-computers.personalComputers.stocklyNixosSystem {
          hostname = "stockly-romainc";
          configuration = ./computers/stockly-romainc/configuration.nix;
          specialArgs = {
            inherit
              by-db
              home-manager
              nixpkgs
              pkgsUnstable
              sops-nix
              stockly-computers
              ;
          };
        };
      };
    };
}