android/build.gradle.kts at master · bar-g/android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
import com.ncorti.ktfmt.gradle.tasks.KtfmtFormatTask

plugins {
	alias(libs.plugins.android.application) apply false
	alias(libs.plugins.kotlinxSerialization) apply false
	alias(libs.plugins.ksp) apply false
	alias(libs.plugins.androidLibrary) apply false
	alias(libs.plugins.compose.compiler) apply false
	alias(libs.plugins.ktfmt)
	alias(libs.plugins.licensee) apply false
    alias(libs.plugins.jetbrains.kotlin.jvm) apply false
	alias(libs.plugins.aboutlibraries) apply false
}

subprojects {
	apply {
		plugin(rootProject.libs.plugins.ktfmt.get().pluginId)
	}

	plugins.withId("org.jetbrains.kotlin.android") {
		extensions.configure<org.jetbrains.kotlin.gradle.dsl.KotlinProjectExtension> {
			jvmToolchain(21)
		}
	}

	plugins.withId("org.jetbrains.kotlin.jvm") {
		extensions.configure<org.jetbrains.kotlin.gradle.dsl.KotlinProjectExtension> {
			jvmToolchain(21)
		}
	}

	tasks.register<KtfmtFormatTask>("format") {
		description = "Format Kotlin code style deviations."
        source = project.fileTree(rootDir)
		include("**/*.kt")
		exclude("**/build/**", ".*generated.*", "**/amneziawg-tools/**", "**/.gradle/**")
	}

	ktfmt {
		kotlinLangStyle()
	}
}