lsads/relbuild.cmd at master · assarbad/lsads · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
@echo off
setlocal ENABLEEXTENSIONS & pushd .
set TGTNAME=lsads
set PRJNAME=%TGTNAME%_release
set SIGURL=https://sourceforge.net/projects/%TGTNAME%
set SIGDESC=%TGTNAME%: List Alternative Data Streams
premake4.exe --release vs2005
call "%~dp0setvcvars.cmd" 2005
:: premake4.exe --release --xp vs2022
:: call "%~dp0setvcvars.cmd" 2022
echo %VCVER_FRIENDLY%
vcbuild.exe /time /rebuild /showenv /M1 /nologo "/htmllog:$(SolutionDir)buildlog.html" "%~dp0%PRJNAME%.vs8.sln" "$ALL"
del /f %PRJNAME%\*.idb
call ollisign.cmd /a %PRJNAME%\*.exe "%SIGURL%" "%SIGDESC%"
:: call :DDKBUILD
rd /s /q "%~dp0%PRJNAME%_intermediate"
set SEVENZIP=%ProgramFiles%\7-Zip\7z.exe
if not exist "%SEVENZIP%" set SEVENZIP=%ProgramFiles(x86)%\7-Zip\7z.exe
for /f %%i in ('hg id -i') do @set RELEASE=%%i
for /f %%i in ('hg id -n') do @set RELEASE=%%i-%RELEASE%
set RELARCHIVE=%~dp0%TGTNAME%-%RELEASE%.7z
if exist "%SEVENZIP%" @(
    pushd "%~dp0%PRJNAME%"
    "%SEVENZIP%" a -y -t7z "%RELARCHIVE%" "*.exe" "*.pdb"
    gpg -ba %RELARCHIVE%
    popd
)
popd & endlocal & goto :EOF

:DDKBUILD
setlocal ENABLEEXTENSIONS & pushd "%~dp0ddkbuild"
call ddkbuild.cmd -W7XP free . -cZ
call ollisign.cmd /a objfre_wxp_x86\i386\*.exe "%%SIGURL%%" "%SIGDESC%"
call ddkbuild.cmd -W7NETX64 free . -cZ
call ollisign.cmd /a objfre_wnet_amd64\amd64\*.exe "%%SIGURL%%" "%SIGDESC%"
set WDKBLD=..\%PRJNAME%\wdk
md "%WDKBLD%"
xcopy /y objfre_wxp_x86\i386\*.exe "%WDKBLD%\"
xcopy /y objfre_wnet_amd64\amd64\*.exe "%WDKBLD%\"
xcopy /y objfre_wxp_x86\i386\*.pdb "%WDKBLD%\"
xcopy /y objfre_wnet_amd64\amd64\*.pdb "%WDKBLD%\"
popd & endlocal