cpp-ekosystem/CMakeLists.txt at main · arkaht/cpp-ekosystem · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
cmake_minimum_required(VERSION 3.11)

#  Setup Ekosystem
project(EKOSYSTEM)
set(CMAKE_CXX_STANDARD 20)
set(EKOSYSTEM_INCLUDE "${CMAKE_CURRENT_SOURCE_DIR}/src")
set(EKOSYSTEM_SOURCE "${EKOSYSTEM_INCLUDE}/ekosystem")
set(EKOSYSTEM_ASSETS "${CMAKE_CURRENT_SOURCE_DIR}/assets")

add_compile_definitions(ENABLE_VISDEBUG)
add_compile_definitions(ENABLE_MEMORY_PROFILER)

#  Require Suprengine
set(SUPRENGINE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/../cpp-suprengine/" CACHE FILEPATH "Path to the suprengine project")
add_subdirectory("${SUPRENGINE_PATH}" "suprengine")

#  Find source files
file(GLOB_RECURSE EKOSYSTEM_SOURCES CONFIGURE_DEPENDS "${EKOSYSTEM_SOURCE}/*.cpp")

#  Declare Ekosystem project
add_executable(EKOSYSTEM)
set_target_properties(EKOSYSTEM PROPERTIES OUTPUT_NAME "ekosystem")
target_include_directories(EKOSYSTEM PRIVATE "${EKOSYSTEM_INCLUDE}")
target_sources(EKOSYSTEM PRIVATE "${EKOSYSTEM_SOURCES}")
target_link_libraries(EKOSYSTEM PRIVATE SUPRENGINE)

#  Setup install rules
#  Install executable
install(TARGETS EKOSYSTEM DESTINATION "bin")
#  Install assets
install(
	DIRECTORY "${EKOSYSTEM_ASSETS}/"
	DESTINATION "bin/assets/ekosystem"
	PATTERN "*.blend" EXCLUDE
	PATTERN "*.blend1" EXCLUDE
	PATTERN "*.afphoto" EXCLUDE
)
install(
	DIRECTORY "${SUPRENGINE_ASSETS}/"
	DESTINATION "bin/assets/suprengine"
	PATTERN "*.blend" EXCLUDE
	PATTERN "*.blend1" EXCLUDE
	PATTERN "*.afphoto" EXCLUDE
)
#  Install DLLs
foreach(FILE ${SUPRENGINE_DLLS})
	install(FILES ${FILE} TYPE BIN)
endforeach()

#  Copy DLLs and assets
suprengine_copy_dlls(EKOSYSTEM)
suprengine_symlink_assets(EKOSYSTEM "ekosystem")