Jenkinsfile.integration-variants

pipeline {
    // Don't set an agent, or it won't parallelize correctly.
    // Each stage should ask for it's own agent
    agent none

    environment {
        // Disable the daemon to prevent parallal issues
        GRADLE_OPTS = '-Dci=true -Dfile.encoding=UTF-8 -Dselenium.wait.timeout=60 -Dorg.gradle.daemon=false'
    }

    tools {
        jdk 'jdk_11_latest'
    }

    options {
        timeout(time: 2, unit: 'HOURS')
        skipStagesAfterUnstable()
    }

    stages {
        stage('Integration Test Variants') {
            parallel {
                stage('Test: Prototype + RequireJS Disabled') {
                    agent {
                        node {
                            label 'ubuntu'
                        }
                    }
                    steps {
                        sh './gradlew tapestry-core:testWithPrototypeAndRequireJsDisabled --continue'
                    }
                    post {
                        always {
                            prefixAndPublishTestResults('testWithPrototypeAndRequireJsDisabled', 'Prototype')
                        }
                    }
                }

                stage('Test: jQuery + RequireJS Disabled') {
                    agent {
                        node {
                            label 'ubuntu'
                        }
                    }
                    steps {
                        sh './gradlew tapestry-core:testWithJqueryAndRequireJsDisabled --continue'
                    }
                    post {
                        always {
                            prefixAndPublishTestResults('testWithJqueryAndRequireJsDisabled', 'jQuery')
                        }
                    }
                }

                stage('Test: Prototype + RequireJS Enabled') {
                    agent {
                        node {
                            label 'ubuntu'
                        }
                    }
                    steps {
                        sh './gradlew tapestry-core:testWithPrototypeAndRequireJsEnabled --continue'
                    }
                    post {
                        always {
                            prefixAndPublishTestResults('testWithPrototypeAndRequireJsEnabled', 'PrototypeRjs')
                        }
                    }
                }
            }
        }
    }

    post {
        fixed    { sendMail('FIXED') }
        unstable { sendMail('UNSTABLE') }
        failure  { sendMail('FAILURE') }
        aborted  { sendMail('ABORTED') }
    }
}

// TEST RESULTS

def prefixAndPublishTestResults(testName, prefix) {
    sh """
        if [ -d "tapestry-core/build/test-results/${testName}" ]; then
            find tapestry-core/build/test-results/${testName} -name "*.xml" -type f -exec sed -i 's/classname="org[.]/classname="${prefix}.org./g' {} +
        fi
    """
    junit(
        testResults: "tapestry-core/build/test-results/${testName}/**/*.xml",
        allowEmptyResults: true
    )
}

// MAIL NOTIFICATIONS

def getChangeLog() {
    def changeSets = currentBuild.changeSets
    if (changeSets.isEmpty()) {
        return "No changes recorded (Manual build or no new commits)."
    }
    return changeSets
        .collectMany { it.items as List }
        .collect { "[${it.author}] ${it.msg}" }
        .join('\n')
}

def sendMail(buildStatus) {
    emailext (
        subject: "[${buildStatus}] ${env.JOB_NAME} - Build #${env.BUILD_NUMBER}",
        body: """
STATUS: ${buildStatus}
Build URL: ${env.BUILD_URL}
Duration: ${currentBuild.durationString.replace(' and counting', '')}

-----------------------------------------------------------
CHANGES
-----------------------------------------------------------
${getChangeLog()}

-----------------------------------------------------------
TEST RESULTS
-----------------------------------------------------------
\${TEST_COUNTS, var="total"} Tests: \${TEST_COUNTS, var="pass"} Passed, \${TEST_COUNTS, var="fail"} Failed, \${TEST_COUNTS, var="skip"} Skipped

-----------------------------------------------------------
FAILED TESTS (if any)
-----------------------------------------------------------
\${FAILED_TESTS, maxTests=10, showStack=false}
        """,
        recipientProviders: [
            developers(), // People who have commits in this build
            requestor()   // The person who manually triggered the build
        ]
    )
}