simcoe-commons/meson.build at master · apache-hb/simcoe-commons · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# SPDX-License-Identifier: Apache-2.0

project(
  'simcoe-commons',
  'cpp',
  version: '0.1.0',
  license: 'Apache-2.0',
  meson_version: '>=0.60.0',
  default_options: [
    'warning_level=3',
    'cpp_std=c++20',
  ],
)

pkg = import('pkgconfig')
url = 'https://github.com/apache-hb/simcoe-commons'

tests_opt = get_option('tests').disable_auto_if(meson.is_subproject())
docs_opt = get_option('docs').disable_auto_if(meson.is_subproject())

gtest_main = dependency(
  'gtest_main',
  required: tests_opt,
)

doxygen = find_program(
  'doxygen',
  required: docs_opt,
)

subdir('modules/concurrent')
subdir('modules/container')
subdir('modules/defer')
subdir('modules/version')

if doxygen.found()
  doxygen_config = configure_file(
    input: 'resources/Doxyfile.in',
    output: 'Doxyfile',
    configuration: {
      'PROJECT_NAME': meson.project_name(),
      'PROJECT_VERSION': meson.project_version(),
      'OUTPUT_DIRECTORY': meson.current_build_dir() / 'docs',
      'INPUT': meson.project_source_root() / 'modules',
      'CLANG_DATABASE_PATH': meson.global_build_root() / 'compile_commands.json',
      'CITE_BIB_FILES': meson.project_source_root() / 'resources' / 'cite.bib',
    },
  )

  run_target(
    'doxygen',
    command: [doxygen, doxygen_config],
  )
endif