flake.nix

{
  description = "jjpr";

  inputs = {
    nixpkgs.url  = "github:NixOS/nixpkgs/nixos-25.11";
    # jj template syntax and CLI flags shift between releases; nixos-25.11
    # ships a version too old for the templates in src/main.rs. Pull jujutsu
    # from nixpkgs-unstable so the dev shell tracks a recent jj.
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    flake-utils.url  = "github:numtide/flake-utils";
    crane.url = "github:ipetkov/crane";
  };

  outputs = { self, nixpkgs, nixpkgs-unstable, rust-overlay, flake-utils, crane, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };
        pkgsUnstable = import nixpkgs-unstable { inherit system; };
        rust = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        craneLib = (crane.mkLib pkgs).overrideToolchain rust;

        src = craneLib.cleanCargoSource ./.;

        craneCommonArgs = {
          inherit src;
          strictDeps = true;
          buildInputs = [] ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [];
        };

        cargoArtifacts = craneLib.buildDepsOnly craneCommonArgs;

        jjpr = craneLib.buildPackage(
          craneCommonArgs // { inherit cargoArtifacts; }
        );
      in
      with pkgs;
      {
        checks = {
          # Make sure it compiles
          inherit jjpr;

          jjpr-clippy = craneLib.cargoClippy ( craneCommonArgs // { inherit cargoArtifacts; } );
          jjpr-fmt = craneLib.cargoFmt { inherit src; };
        };
        packages.default = jjpr;
        apps.default = flake-utils.lib.mkApp { drv = jjpr; };
        devShells.default = mkShell {
          buildInputs = [
            rust
            pkgsUnstable.jujutsu
          ];
        };
      }
    );
}