build.zig

const std = @import("std");

const Connection = enum {
    client,
    server,
};

pub fn build(b: *std.Build) void {
    // target & optimize
    const target = b.standardTargetOptions(.{});
    const optimize = b.standardOptimizeOption(.{});

    // glfw import
    const zglfw = b.dependency("zglfw", .{
        .target = target,
        .optimize = optimize,
    });

    // stbi import
    const zstbi = b.dependency("zstbi", .{
        .target = target,
        .optimize = optimize,
    });

    // gl + glu import (headers)
    const GL = b.addTranslateC(.{
        .target = target,
        .optimize = optimize,
        .root_source_file = b.path("import.h"),
        .link_libc = true,
    });

    const mc_options = b.addOptions();
    // fullscreen mode
    const fullscreen = b.option(bool, "fullscreen", "Whether fullscreen mode is enabled (rd-160052+)");
    mc_options.addOption(?bool, "fullscreen", fullscreen);

    // get version from build command (-Dversion=<this>)
    const maybe_version = b.option([]const u8, "version", "What Minecraft version to build (e.g. rd-132211)");
    const version = maybe_version orelse "c0.0.12a-dev";

    // package minecraft version being run as a module
    const minecraft = b.addModule("minecraft", .{
        .root_source_file = b.path(b.fmt("src/{s}/minecraft.zig", .{version})),
        .target = target,
        .imports = &.{
            .{ .name = "gl", .module = GL.createModule() },
            .{ .name = "glfw", .module = zglfw.module("root") },
            .{ .name = "stbi", .module = zstbi.module("root") },
        },
    });
    minecraft.addOptions("options", mc_options);

    const exe_options = b.addOptions();
    // client/server option
    const connection = b.option([]const u8, "connection", "Is either \"server\" or \"client\"") orelse "client";
    const con_opt = std.meta.stringToEnum(Connection, connection) orelse {
        std.debug.print("ERROR: connection must be either \"server\" or \"client\".\n", .{});
        return;
    };
    exe_options.addOption(Connection, "connection", con_opt);

    // combine into executable
    const exe = b.addExecutable(.{
        .name = "Zinecraft",
        .root_module = b.createModule(.{
            .root_source_file = b.path("src/main.zig"),
            .target = target,
            .optimize = optimize,
            .imports = &.{
                .{ .name = "gl", .module = GL.createModule() },
                .{ .name = "glfw", .module = zglfw.module("root") },
                .{ .name = "stbi", .module = zstbi.module("root") },
                .{ .name = "minecraft", .module = minecraft },
            },
        }),
    });
    exe.root_module.addOptions("options", exe_options);

    exe.root_module.linkSystemLibrary("GL", .{});
    exe.root_module.linkSystemLibrary("GLU", .{});

    if (target.result.os.tag != .emscripten) {
        exe.root_module.linkLibrary(zglfw.artifact("glfw"));
    }

    b.installArtifact(exe);

    const run_step = b.step("run", "Run the app");

    const run_cmd = b.addRunArtifact(exe);
    run_step.dependOn(&run_cmd.step);
    run_cmd.step.dependOn(b.getInstallStep());

    if (b.args) |args| {
        run_cmd.addArgs(args);
    }

    const exe_tests = b.addTest(.{
        .root_module = exe.root_module,
    });
    const run_exe_tests = b.addRunArtifact(exe_tests);

    const test_step = b.step("test", "Run tests");
    test_step.dependOn(&run_exe_tests.step);
}