build.gradle

plugins {
	id 'java'
	id 'org.springframework.boot' version '3.2.1'
	id 'io.spring.dependency-management' version '1.1.4'
}

ext.getVersionFromGitTag = { fallbackVersion ->
	def gitTag = 'git describe --tags --exact-match HEAD 2>/dev/null)'.execute().text.trim()
	def v = !gitTag.isEmpty() && gitTag.startsWith('v') ? gitTag.substring(1) : fallbackVersion
	println "Setting project version to: $v"
	return v
}

group = 'de.tutum'
version = getVersionFromGitTag('0.1.0-SNAPSHOT')

java {
	sourceCompatibility = '21'
	targetCompatibility = '21'
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

repositories {
	mavenCentral()

	maven {
		url "https://gitlab.lrz.de/api/v4/groups/190013/-/packages/maven"
		credentials(HttpHeaderCredentials) {
			name = tutumGitlabUsername // the variable resides in $GRADLE_USER_HOME/gradle.properties
			value = tutumGitlabToken // the variable resides in $GRADLE_USER_HOME/gradle.properties
		}
		authentication {
			header(HttpHeaderAuthentication)
		}
	}
}

def springBootVersion = "3.1.1"
def lombokVersion = "1.18.30"
def grpcVersion = "1.60.1"
def testcontainersVersion = "1.19.0"

dependencies {
	implementation "org.springframework.boot:spring-boot-starter-web:${springBootVersion}"
	implementation "org.springframework.boot:spring-boot-starter-data-jpa:${springBootVersion}"
	implementation "org.springframework.boot:spring-boot-starter-actuator:${springBootVersion}"

	implementation 'io.hypersistence:hypersistence-utils-hibernate-62:3.7.0'
	implementation 'org.flywaydb:flyway-core'

	implementation 'de.tutum:Contracts:0.1.2'

	// --- Runtime
	runtimeOnly 'org.postgresql:postgresql'
	runtimeOnly "io.grpc:grpc-netty-shaded:${grpcVersion}"

	// --- Compile
	compileOnly "org.projectlombok:lombok:${lombokVersion}"

	// --- Annotations
	annotationProcessor "org.projectlombok:lombok:${lombokVersion}"
	annotationProcessor 'org.hibernate.orm:hibernate-jpamodelgen:6.2.4.Final'

	// --- Test Implementation
	testImplementation "org.springframework.boot:spring-boot-starter-test:${springBootVersion}"
	testImplementation "org.springframework.boot:spring-boot-testcontainers:${springBootVersion}"
	testImplementation "org.testcontainers:junit-jupiter:${testcontainersVersion}"
	testImplementation "org.testcontainers:postgresql:${testcontainersVersion}"

	// --- Test Compile
	testCompileOnly "org.projectlombok:lombok:${lombokVersion}"

	// --- Test Annotations
	testAnnotationProcessor "org.projectlombok:lombok:${lombokVersion}"
}

dependencyManagement {
	imports {
		mavenBom "org.testcontainers:testcontainers-bom:${testcontainersVersion}"
	}
}

jar {
	enabled = false
}

test {
	useJUnitPlatform()
}