dppd_plotnine/flake.nix at master · TyberiusPrime/dppd_plotnine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
{
  description = "dppd development falke";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-24.11";
    uv2nix.url = "github:/adisbladis/uv2nix";
    uv2nix.inputs.nixpkgs.follows = "nixpkgs";
    pyproject-nix.url = "github:/nix-community/pyproject.nix";
    pyproject-nix.inputs.nixpkgs.follows = "nixpkgs";
    uv2nix.inputs.pyproject-nix.follows = "pyproject-nix";
    pyproject-build-systems = {
      url = "github:pyproject-nix/build-system-pkgs";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.uv2nix.follows = "uv2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    #uv2nix_hammer_overrides.url = "github:TyberiusPrime/uv2nix_hammer_overrides";
  };
  outputs = {
    nixpkgs,
    uv2nix,
    pyproject-build-systems,
    #uv2nix_hammer_overrides,
    ...
  }: let
    pyproject-nix = uv2nix.inputs.pyproject-nix;
    workspace = uv2nix.lib.workspace.loadWorkspace {workspaceRoot = ./.;};

    pkgs = import nixpkgs {
      system = "x86_64-linux";
      config.allowUnfree = true;
    };

    # Generate overlay
    overlay = workspace.mkPyprojectOverlay {
      sourcePreference = "wheel";
    };
    pyprojectOverrides = final: prev: {
      dppd = prev.dppd.overrideAttrs (old: {
        nativeBuildInputs = old.nativeBuildInputs ++ (final.resolveBuildSystem {setuptools = [];});
      });
    };
    #pyprojectOverrides = final: prev: {} ;
    interpreter = pkgs.python313;
    spec = {
      dppd-plotnine = ["dev"];
    };

    # Construct package set
    pythonSet' =
      (pkgs.callPackage pyproject-nix.build.packages {
        python = interpreter;
      })
      .overrideScope
      (
        pkgs.lib.composeManyExtensions [
          pyproject-build-systems.overlays.default
          overlay
          pyprojectOverrides
        ]
      );

    # Override host packages with build fixups
    pythonSet = pythonSet'.pythonPkgsHostHost.overrideScope pyprojectOverrides;
    virtualEnv = pythonSet.mkVirtualEnv "dppd-ven" spec;
  in {
    #packages.x86_64-linux.default = defaultPackage;
    devShell.x86_64-linux = pkgs.mkShell {
      packages = [
        virtualEnv
      ];
      shellHook = ''
        # Undo dependency propagation by nixpkgs.
        unset PYTHONPATH
      '';
    };
  };
}