steam-min-cpp/CMakeLists.txt at main · SteamCPP/steam-min-cpp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
cmake_minimum_required(VERSION 3.21)

project(SteamClient VERSION 1.0.0 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

include(CTest)

option(BUILD_SHARED_LIBS "Build shared libraries" OFF)
option(BUILD_EXAMPLES "Build SteamClient examples" OFF)
option(STEAMCLIENT_ENABLE_LOGGING "Enable spdlog logging" OFF)

## == MODULES == ##
include(cmake/dependencies.cmake)
include(cmake/protobuf.cmake)

## == SOURCES == ##
file(GLOB_RECURSE SOURCES CONFIGURE_DEPENDS
    ${CMAKE_CURRENT_SOURCE_DIR}/src/*.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/src/*.cc
)

add_library(SteamClient
    ${SOURCES}
    ${GENERATED_PROTO_SRCS}
)

## == OPTIONAL LOGGING == ##
include(cmake/logging.cmake)

target_link_libraries(SteamClient
    PUBLIC
        Boost::system
        protobuf::libprotobuf
        ${CRYPTOPP_LIB}
    PRIVATE
        absl::check
        absl::log
        CURL::libcurl
)

## == INCLUDES == ##
target_include_directories(SteamClient
    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:include>
        $<BUILD_INTERFACE:${PROTO_OUTPUT_DIR}>
    PRIVATE
        ${CMAKE_CURRENT_SOURCE_DIR}/src
)

## = WINDOWS NETWORKING == ##
if(WIN32)
    target_link_libraries(SteamClient PRIVATE ws2_32)
    target_compile_definitions(SteamClient PRIVATE _WIN32_WINNT=0x0601)
endif()

## == TESTING == ##
if(BUILD_TESTING)
    add_subdirectory(test)
endif()

## == EXAMPLES == ##
if(BUILD_EXAMPLES)
    add_subdirectory(examples)
endif()

## == VERSIONING == ##
configure_file(
    ${CMAKE_CURRENT_SOURCE_DIR}/include/steamclient/version.hpp.in
    ${CMAKE_CURRENT_BINARY_DIR}/generated/steamclient/version.hpp
)

target_include_directories(SteamClient PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/generated>
    $<INSTALL_INTERFACE:include>
)

set_target_properties(SteamClient PROPERTIES
    VERSION ${PROJECT_VERSION}
    SOVERSION ${PROJECT_VERSION_MAJOR}
)

write_basic_package_version_file(
    ${CMAKE_CURRENT_BINARY_DIR}/SteamClientConfigVersion.cmake
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY SameMajorVersion
)

install(FILES
    ${CMAKE_CURRENT_BINARY_DIR}/SteamClientConfigVersion.cmake
    DESTINATION lib/cmake/SteamClient
)

install(FILES
    ${CMAKE_CURRENT_BINARY_DIR}/generated/steamclient/version.hpp
    DESTINATION include/steamclient
)

## == PACKAGING == ##
include(CMakePackageConfigHelpers)

configure_package_config_file(
    cmake/SteamClientConfig.cmake.in
    ${CMAKE_CURRENT_BINARY_DIR}/SteamClientConfig.cmake
    INSTALL_DESTINATION lib/cmake/SteamClient
)

install(TARGETS SteamClient
    EXPORT SteamClientTargets
    ARCHIVE DESTINATION lib
    LIBRARY DESTINATION lib
    RUNTIME DESTINATION bin
)

install(DIRECTORY include/ DESTINATION include)

install(EXPORT SteamClientTargets
    FILE SteamClientTargets.cmake
    NAMESPACE SteamClient::
    DESTINATION lib/cmake/SteamClient
)

install(FILES
    ${CMAKE_CURRENT_BINARY_DIR}/SteamClientConfig.cmake
    DESTINATION lib/cmake/SteamClient
)

add_library(SteamClient::SteamClient ALIAS SteamClient)