From 46c940c933abeb56f12995dc8accfed5789cbd22 Mon Sep 17 00:00:00 2001
From: MikenRafter <mikenrafter@protonmail.com>
Date: Sun, 1 Nov 2026 04:25:59 -0700
Subject: [PATCH 1/2] Pin the development toolchain used by Edge

---
 flake.lock | 44 ++++++++++++++++++++++++++++++++++++++++++++
 flake.nix  | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)
 create mode 100644 flake.lock
 create mode 100644 flake.nix

diff --git a/flake.lock b/flake.lock
new file mode 100644
index 00000000..8000e13c
--- /dev/null
+++ b/flake.lock
@@ -0,0 +1,44 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1790046670,
+        "narHash": "sha256-MYiI+CzL0tuWgRPjGsKCDHqYs2T3OzMlMQWOYWG0qso=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "6774f7bc253789b113a4f39285dc0fa100abeacc",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixos-unstable",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "nixpkgs-flutter": {
+      "locked": {
+        "lastModified": 1774840819,
+        "narHash": "sha256-V9TPFnbTQx9bDyVKuHpYi/0fC5qTgxDeHkST0RNAuTk=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "27dfede99da61fd1ead9d4a2fa92bc9c242e83d2",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "27dfede99da61fd1ead9d4a2fa92bc9c242e83d2",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs",
+        "nixpkgs-flutter": "nixpkgs-flutter"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}
diff --git a/flake.nix b/flake.nix
new file mode 100644
index 00000000..62def2ad
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,52 @@
+{
+  description = "OpenStrap analytics Dart and Flutter development environment";
+
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+  # Same Flutter/Dart release as ../edge and its CI.
+  inputs.nixpkgs-flutter.url =
+    "github:NixOS/nixpkgs/27dfede99da61fd1ead9d4a2fa92bc9c242e83d2";
+
+  outputs = { nixpkgs, nixpkgs-flutter, ... }:
+    let
+      systems = [ "x86_64-linux" "aarch64-linux" ];
+      forAllSystems = nixpkgs.lib.genAttrs systems;
+    in {
+      devShells = forAllSystems (system:
+        let
+          pkgs = import nixpkgs { inherit system; };
+          flutterPkgs = import nixpkgs-flutter {
+            inherit system;
+            config.allowUnfree = true;
+          };
+          flutter = flutterPkgs.flutterPackages.v3_41;
+          tools = with pkgs; [
+            flutter git ripgrep jq python3 gnumake unzip which
+            clang cmake ninja pkg-config
+          ];
+          fhs = pkgs.buildFHSEnv {
+            name = "analytics-fhs";
+            targetPkgs = p: tools ++ (with p; [
+              bashInteractive zlib libcxx ncurses5 gtk3 fontconfig libGL
+            ]);
+            profile = ''
+              export IN_ANALYTICS_FHS=1
+            '';
+            runScript = pkgs.writeShellScript "analytics-fhs-run" ''
+              if [[ $# -eq 0 ]]; then exec bash; else exec "$@"; fi
+            '';
+          };
+        in {
+          default = pkgs.mkShell {
+            packages = tools ++ [ fhs ];
+            shellHook = ''
+              # Let the packaged Flutter wrapper select its complete SDK,
+              # including prebuilt engine/test artifacts.
+              unset FLUTTER_ROOT
+              if [[ -z "$IN_ANALYTICS_FHS" && $- == *i* ]]; then
+                exec analytics-fhs
+              fi
+            '';
+          };
+        });
+    };
+}

From d64b77c909a471a4fa5720faf2b67dab61852941 Mon Sep 17 00:00:00 2001
From: MikenRafter <mikenrafter@protonmail.com>
Date: Fri, 13 Nov 2026 06:56:07 -0700
Subject: [PATCH 2/2] Start the shell under nounset when IN_ANALYTICS_FHS is
 unset

---
 flake.nix | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/flake.nix b/flake.nix
index 62def2ad..4d3d0ad6 100644
--- a/flake.nix
+++ b/flake.nix
@@ -42,7 +42,7 @@
               # Let the packaged Flutter wrapper select its complete SDK,
               # including prebuilt engine/test artifacts.
               unset FLUTTER_ROOT
-              if [[ -z "$IN_ANALYTICS_FHS" && $- == *i* ]]; then
+              if [[ -z "''${IN_ANALYTICS_FHS:-}" && $- == *i* ]]; then
                 exec analytics-fhs
               fi
             '';