batch-transfer-plugin/build.gradle at main · NrgXnat/batch-transfer-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
buildscript {
    ext {
        vXnat = "1.9.3.3"
        pluginAppName = "Batch Transfer Plugin"
    }
}

plugins {
    id "idea"
    id "java"
    id "maven-publish"
    id "io.spring.dependency-management" version "1.0.9.RELEASE"
    id "io.freefair.lombok" version "8.6"
    id "net.linguica.maven-settings" version "0.5"
}

group "org.nrg.xnatx.plugins"
version "1.1.1"
description "XNAT Batch Transfer Plugin"

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenLocal()
    maven { url "https://nrgxnat.jfrog.io/nrgxnat/libs-release" }
    maven { url "https://nrgxnat.jfrog.io/nrgxnat/libs-snapshot" }
    maven { url "https://www.dcm4che.org/maven2" }
    mavenCentral()
}

dependencyManagement {
    imports {
        mavenBom("org.nrg:parent:${vXnat}")
    }
}
configurations.all {
    resolutionStrategy.capabilitiesResolution.withCapability("com.google.collections:google-collections") {
        selectHighestVersion()
    }
}
dependencies {
    implementation platform("org.nrg:parent:${vXnat}")

    annotationProcessor "org.nrg:framework"
    implementation "org.nrg.xnat:web"
    implementation "org.nrg.xdat:core"
    implementation "org.nrg:dicom-xnat-util"
    implementation "org.springframework:spring-beans"
    implementation "org.springframework:spring-context"
    implementation "org.springframework:spring-jms"
    implementation "org.springframework:spring-tx"
    implementation 'org.springframework:spring-webmvc'
    implementation "io.springfox:springfox-swagger2"

    testImplementation "log4j:log4j"
    testImplementation "junit:junit"
    testImplementation "org.hamcrest:hamcrest-library"
    testImplementation "org.mockito:mockito-core:4.8.0"
    testImplementation "org.mockito:mockito-inline:4.8.0"
    testImplementation "org.springframework:spring-test"
}

test {
    useJUnit()
}

task sourceJar(type: Jar, dependsOn: classes) {
    classifier "sources"
    from sourceSets.main.allSource
}

task javadocJar(type: Jar) {
    classifier "javadoc"
    from javadoc.destinationDir
}

def buildDate = new Date()
def buildNumber = System.getenv().BUILD_NUMBER?.toInteger() ?: "Manual"

logger.info "Build-Date:   ${buildDate}"
logger.info "Build-Number: ${buildNumber}"

publishing {
    publications {
        mavenJava(MavenPublication) {

            artifacts {
                artifact sourceJar
                artifact javadocJar
                artifact jar
            }

            pom.withXml {
                def root = asNode()
                root.appendNode("name", "XNAT Batch Transfer Plugin")
                root.appendNode("inceptionYear", "2021")

                def license = root.appendNode("licenses").appendNode("license")
                license.appendNode("name", "Simplified BSD 2-Clause License")
                license.appendNode("url", "https://xnat.org/about/license.php")
                license.appendNode("distribution", "repo")

                def developers = root.appendNode("developers")
                def tim = developers.appendNode("developer")
                tim.appendNode("id", "timo")
                tim.appendNode("name", "Timothy Olsen")
                tim.appendNode("email", "tim@radiologics.com")

                def kelsey = developers.appendNode("developer")
                kelsey.appendNode("id", "kelseym")
                kelsey.appendNode("name", "Matt Kelsey")
                kelsey.appendNode("email", "kelseym@wustl.edu")
            }
        }
    }
    repositories {
        maven {
            if (project.version.endsWith("-SNAPSHOT")) {
                url "https://nrgxnat.jfrog.io/nrgxnat/libs-snapshot-local"
            } else {
                url "https://nrgxnat.jfrog.io/nrgxnat/libs-release-local"
            }
            // The value for name must match <id> in ~/.m2/settings.xml
            name = "XNAT_Artifactory"
        }
    }
}

def propertyWithDefault(String name, Object value) {
    hasProperty(name) ? property(name) : value
}