Map/SoftSDK.pri at master · MJYCo-Ltd/Map · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
# Attention Debug   version always suffix with a d,
#           Release version always not.
# For example
# CONFIG(debug, debug|release){
#         LIBS += -losgd
#}else{
#         LIBS += -losg
#}
#
#Attention DLLDESTDIR only useful in windows
#          This will only copy exe or dll to DLLDESTDIR
lessThan(QT_MAJOR_VERSION, 6):CONFIG += c++11
greaterThan(QT_MAJOR_VERSION, 5):CONFIG += c++17

INCLUDEPATH *= $$PWD/Inc
win32{
include(Path.pri)
    DEFINES -= UNICODE
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CXXFLAGS += /wd"4100"
    QMAKE_CXXFLAGS += /MP

    LIBS *= -L$$PWD/Lib
    contains(TEMPLATE, "app"){
        DESTDIR = $$PWD/../Bin
    }else{
        DLLDESTDIR = $$PWD/../Bin
        contains(SDK_CONFIG,PLOT){
            DLLDESTDIR = $$DLLDESTDIR/MapPlugin/Plot
        }else{
            contains(SDK_CONFIG,TOOL){
            DLLDESTDIR = $$DLLDESTDIR/MapPlugin/Tool
            }else{
                DESTDIR = $$PWD/Lib
            }
        }
    }
}

unix{
    DESTDIR = $$PWD/../Bin
    contains(SDK_CONFIG,PLOT){
        DESTDIR = $$DESTDIR/MapPlugin/Plot
    }else{
        contains(SDK_CONFIG,TOOL){
            DESTDIR = $$DESTDIR/MapPlugin/Tool
        }
    }
    LIBS *= -L$$PWD/../Bin
    contains(TEMPLATE, "app"){
        QMAKE_LFLAGS += -Wl,-rpath=.:./osglib:./stklib
    }else{
        QMAKE_CXXFLAGS += -fvisibility=hidden
    }
}

contains(SDK_CONFIG,VR){
    win32{
        INCLUDEPATH *=$${NEWGL3PATH}/include
        LIBS *= -L$${NEWGL3PATH}/lib
    }

    CONFIG (debug, debug|release){
        LIBS *= -lopenvr_api64d
    }else{
        LIBS *= -lopenvr_api64
    }
}

contains(SDK_CONFIG,OSG){

# include file
    win32{
        INCLUDEPATH *=$${NEWGL3PATH}/include
        LIBS *= -L$${NEWGL3PATH}/lib
        msvc{
            CONFIG (debug, debug|release){
         #threads
                LIBS *= -lOpenThreadsd
         # osg libs
                LIBS *= -losgd -losgDBd -losgGAd -losgSimd -losgViewerd -losgUtild -losgTextd -losgManipulatord
         #osgEarth libs
                LIBS *= -losgEarthd
            }else{
                LIBS *= -lOpenThreads
                LIBS *= -losg -losgDB -losgGA -losgSim -losgViewer -losgUtil  -losgText  -losgManipulator
                LIBS *= -losgEarth
            }
        }
        mingw{
            LIBS *= -lOpenThreads
            LIBS *= -losg -losgDB -losgGA -losgSim -losgViewer -losgUtil  -losgText  -losgManipulator
            LIBS *= -losgEarth
        }
    }

    unix{
        LIBS *= -L$$PWD/../Bin/osglib
        LIBS *= -lOpenThreads
        LIBS *= -losg -losgDB -losgGA -losgSim -losgViewer -losgUtil  -losgText  -losgManipulator
        LIBS *= -losgEarth
    }
}

contains(SDK_CONFIG,Satellite){
    MathPath=$${PWD}/../VersionMath
    INCLUDEPATH *= $${MathPath}/Inc $${MathPath}/Inc/Math
    win32:LIBS *= -L$${MathPath}/Lib
    unix:LIBS *= -L$$PWD/../Bin/stklib
    CONFIG (debug, debug|release){
        LIBS *= -lSatellited -lMathd -lGisMathd -lSatelliteToolKitd
    }else{
        LIBS *= -lSatellite -lMath -lGisMath -lSatelliteToolKit
    }
}

contains(SDK_CONFIG,OsgExtern){
    CONFIG (debug, debug|release){
        LIBS *= -lOsgExternd
    }else{
        LIBS *= -lOsgExtern
    }
}
contains(SDK_CONFIG,ExternShape){
    CONFIG (debug, debug|release){
        LIBS *= -lExternShaped
    }else{
        LIBS *= -lExternShape
    }
}

contains(SDK_CONFIG,SceneCore){
    CONFIG (debug, debug|release){
        LIBS *= -lSceneCored
    }else{
        LIBS *= -lSceneCore
    }
}

# This can suffix a d by itself,if is a debug version
CONFIG(debug, debug|release) {
    OBJECTS_DIR = $$PWD/debug/$$TARGET/obj
    MOC_DIR = $$PWD/debug/$$TARGET/moc
    UI_DIR = $$PWD/debug/$$TARGET/UI
    TARGET = $$join(TARGET,,,d)
}else{
    OBJECTS_DIR = $$PWD/release/$$TARGET/obj
    MOC_DIR = $$PWD/release/$$TARGET/moc
    UI_DIR = $$PWD/release/$$TARGET/UI
}