CMakeLists.txt

#   ____  _             _       
#  |  _ \| |_   _  __ _(_)_ __  
#  | |_) | | | | |/ _` | | '_ \ 
#  |  __/| | |_| | (_| | | | | |
#  |_|   |_|\__,_|\__, |_|_| |_|
#                 |___/         
# A Template for RerunPlugin, a Sink Plugin
# Generated by the command: plugin -t sink -d rerun_plugin -s rerun
# Hostname: Fram-IV.local
# Current working directory: /Users/p4010/Develop/MADS_plugins
# Creation date: 2025-09-08T16:35:50.334+0200
# NOTICE: MADS Version 1.3.5
cmake_minimum_required(VERSION 3.28)
project(rerun VERSION 2.3.0 LANGUAGES CXX)
if(CMAKE_BUILD_TYPE STREQUAL "")
  set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build." FORCE)
endif()
if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT) 
  set(CMAKE_INSTALL_PREFIX "/Users/p4010/usr/local/lib" CACHE PATH "Install path prefix, prepended onto install directories." FORCE)
endif()
message(STATUS "CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}")
set(PLUGIN_SUFFIX "" CACHE STRING "Suffix for the plugin file, identifying the architecture, e.g. arm64, x86_64, etc.")
if(PLUGIN_SUFFIX STREQUAL "")
  message(WARNING "No PLUGIN_SUFFIX set, using default plugin name. In multi-platform environment with OTA plugins it is advised to set PLUGIN_SUFFIX to the architecture, e.g. arm64, x86_64, etc.")
else()
  message(STATUS "PLUGIN_SUFFIX set to: ${PLUGIN_SUFFIX}")
endif()

set(WITH_ABSCISSA FALSE CACHE BOOL "Enable abscissa scale on bar charts (requires rerun_sdk > 0.24.1)")
set(RERUN_USE_SYSTEM_ARROW OFF CACHE BOOL "Use a system-installed Apache Arrow package instead of letting rerun_sdk build Arrow")
set(RERUN_HOMEBREW_PREFIX "/opt/homebrew" CACHE PATH "Homebrew prefix used to locate apache-arrow and its CMake dependencies")

# PROJECT SETTINGS #############################################################
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(SRC_DIR ${CMAKE_CURRENT_LIST_DIR}/src)

if(UNIX AND NOT APPLE)
  set(LINUX TRUE)
  add_compile_options(-fPIC)
endif()

# DEPENDENCIES #################################################################
include(FetchContent)
# pugg is for the plugin system
FetchContent_Declare(pugg 
  GIT_REPOSITORY https://github.com/pbosetti/pugg.git
  GIT_TAG        1.1.0
  GIT_SHALLOW    TRUE
  EXCLUDE_FROM_ALL
)

set(BUILD_TESTING OFF CACHE INTERNAL "")
set(JSON_BuildTests OFF CACHE INTERNAL "")
FetchContent_Declare(json
  URL https://github.com/nlohmann/json/releases/download/v3.11.3/json.tar.xz
  DOWNLOAD_EXTRACT_TIMESTAMP TRUE
  EXCLUDE_FROM_ALL
)

FetchContent_Declare(threadpool
  GIT_REPOSITORY https://github.com/bshoshany/thread-pool.git
  GIT_TAG v5.0.0
  GIT_SHALLOW TRUE
  EXCLUDE_FROM_ALL
)

set(EIGEN_BUILD_DOC OFF CACHE INTERNAL "")
set(EIGEN_BUILD_TESTING OFF CACHE INTERNAL "")
set(EIGEN_BUILD_PKGCONFIG OFF CACHE INTERNAL "")
set(BUILD_TESTING OFF CACHE INTERNAL "")
FetchContent_Declare(Eigen
  GIT_REPOSITORY https://gitlab.com/libeigen/eigen.git
  GIT_TAG 3.4.0
  GIT_SHALLOW TRUE
  EXCLUDE_FROM_ALL
)

# Download and configure rerun SDK
FetchContent_Declare(rerun_sdk
  URL https://github.com/rerun-io/rerun/releases/download/0.33.0/rerun_cpp_sdk.zip
  EXCLUDE_FROM_ALL
  # Arrow (a rerun dependency) is downloaded as a tarball, so "git apply" in
  # rerun's own PATCH_COMMAND always fails silently. We replace it with a
  # cmake -P script that applies the same fixes without needing git history.
  # See patches/patch_arrow_cmake4.cmake for details.
  PATCH_COMMAND ${CMAKE_COMMAND}
    -DPATCHES_DIR=${CMAKE_CURRENT_SOURCE_DIR}/patches
    -P ${CMAKE_CURRENT_SOURCE_DIR}/patches/patch_rerun_sdk.cmake
)

if(RERUN_USE_SYSTEM_ARROW)
  set(RERUN_DOWNLOAD_AND_BUILD_ARROW OFF CACHE BOOL "Use system Apache Arrow for rerun_sdk" FORCE)
  set(RERUN_ARROW_LINK_SHARED ON CACHE BOOL "Link rerun_sdk against the shared Arrow library" FORCE)

  if(APPLE AND EXISTS "${RERUN_HOMEBREW_PREFIX}/opt/apache-arrow/lib/cmake/Arrow")
    set(Arrow_DIR "${RERUN_HOMEBREW_PREFIX}/opt/apache-arrow/lib/cmake/Arrow"
        CACHE PATH "Path to ArrowConfig.cmake" FORCE)

    set(_rerun_homebrew_prefixes
        "${RERUN_HOMEBREW_PREFIX}"
        "${RERUN_HOMEBREW_PREFIX}/opt/apache-arrow"
        "${RERUN_HOMEBREW_PREFIX}/opt/lz4"
    )
    file(GLOB _rerun_homebrew_aws_prefixes "${RERUN_HOMEBREW_PREFIX}/opt/aws*")
    list(APPEND _rerun_homebrew_prefixes ${_rerun_homebrew_aws_prefixes})
    list(REMOVE_DUPLICATES _rerun_homebrew_prefixes)

    foreach(_rerun_prefix IN LISTS _rerun_homebrew_prefixes)
      if(EXISTS "${_rerun_prefix}")
        list(APPEND CMAKE_PREFIX_PATH "${_rerun_prefix}")
      endif()
    endforeach()
    list(REMOVE_DUPLICATES CMAKE_PREFIX_PATH)
    set(CMAKE_PREFIX_PATH "${CMAKE_PREFIX_PATH}" CACHE STRING "Prefix path for find_package()" FORCE)

    message(STATUS "Using system Apache Arrow from ${Arrow_DIR}")
  else()
    message(FATAL_ERROR
      "RERUN_USE_SYSTEM_ARROW is ON, but apache-arrow was not found under "
      "${RERUN_HOMEBREW_PREFIX}/opt/apache-arrow/lib/cmake/Arrow")
  endif()
endif()

FetchContent_MakeAvailable(pugg json rerun_sdk threadpool Eigen)

FetchContent_Populate(plugin 
  GIT_REPOSITORY https://github.com/pbosetti/mads_plugin.git
  GIT_TAG        v2.3-P7
  GIT_SHALLOW    TRUE
  SUBBUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/_deps/plugin-subbuild
  SOURCE_DIR ${CMAKE_CURRENT_BINARY_DIR}/_deps/plugin-src
  BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/_deps/plugin-build
)

include_directories(
  ${plugin_SOURCE_DIR}/src
  ${rerun_sdk_SOURCE_DIR}/src
  ${threadpool_SOURCE_DIR}/include

)

# MACROS #######################################################################
# Call: add_plugin(name [SRCS src1 src2 ...] [LIBS lib1 lib2 ...])
#       the source file ${SRC_DIR}/plugin/<name>.cpp is implicitly added
macro(add_plugin name)
  # on MacOS only, plugins can be compiled as executables
  set(multiValueArgs LIBS SRCS)
  cmake_parse_arguments(plugin "" "" "${multiValueArgs}" ${ARGN})
  if (APPLE)
    add_executable(${name} ${SRC_DIR}/${name}.cpp ${plugin_SRCS})
    set_target_properties(${name} PROPERTIES ENABLE_EXPORTS TRUE)
    set(${name}_EXEC ${name}.plugin)
  else()
    add_library(${name} SHARED ${SRC_DIR}/${name}.cpp ${plugin_SRCS})
    add_executable(${name}_main ${SRC_DIR}/${name}.cpp ${plugin_SRCS})
    target_link_libraries(${name}_main PRIVATE pugg ${plugin_LIBS})
    set_target_properties(${name}_main PROPERTIES OUTPUT_NAME ${name})
    if(WIN32)
      set_target_properties(${name}_main PROPERTIES
        ARCHIVE_OUTPUT_NAME ${name}_main
        PDB_NAME ${name}_main
      )
    endif()
    set(${name}_EXEC ${name})
    list(APPEND TARGET_LIST ${name}_main)
  endif()
  target_link_libraries(${name} PRIVATE pugg ${plugin_LIBS})
  set_target_properties(${name} PROPERTIES PREFIX "")
  if (PLUGIN_SUFFIX)
    set_target_properties(${name} PROPERTIES SUFFIX "_${PLUGIN_SUFFIX}.plugin")
    target_compile_definitions(${name} PRIVATE PLUGIN_NAME="${name}_${PLUGIN_SUFFIX}")
  else()
    set_target_properties(${name} PROPERTIES SUFFIX ".plugin")
    target_compile_definitions(${name} PRIVATE PLUGIN_NAME="${name}")
  endif()
  list(APPEND TARGET_LIST ${name})
endmacro()


# BUILD SETTINGS ###############################################################
if (APPLE)
  set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
  include_directories(/opt/homebrew/include)
  link_directories(/opt/homebrew/lib)
else()
  set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib;/usr/local/lib")
endif()
include_directories(${json_SOURCE_DIR}/include)

# These plugins are always build and use for testing
add_plugin(rerunner LIBS rerun_sdk  Eigen3::Eigen SRCS ${SRC_DIR}/moving_window_stats.cpp)
add_dependencies(rerunner rerun_sdk)
if(WITH_ABSCISSA)
  target_compile_definitions(rerunner PUBLIC WITH_ABSCISSA)
endif()


# INSTALL ######################################################################
if(APPLE)
  install(TARGETS ${TARGET_LIST}
    LIBRARY DESTINATION lib
    RUNTIME DESTINATION lib
    ARCHIVE DESTINATION lib
  )
else()
  install(TARGETS ${TARGET_LIST}
    LIBRARY DESTINATION lib
    RUNTIME DESTINATION bin
    ARCHIVE DESTINATION lib
  )
endif()


# PACKAGE #######################################################################
string(TOLOWER "${CMAKE_SYSTEM_NAME}" PACKAGE_OS_NAME)
if(APPLE AND CMAKE_OSX_ARCHITECTURES)
  list(LENGTH CMAKE_OSX_ARCHITECTURES PACKAGE_OSX_ARCHITECTURES_COUNT)
  if(PACKAGE_OSX_ARCHITECTURES_COUNT GREATER 1)
    set(PACKAGE_ARCH_NAME "universal")
  else()
    set(PACKAGE_ARCH_NAME "${CMAKE_OSX_ARCHITECTURES}")
  endif()
else()
  set(PACKAGE_ARCH_NAME "${CMAKE_SYSTEM_PROCESSOR}")
endif()
if(PACKAGE_ARCH_NAME STREQUAL "")
  set(PACKAGE_ARCH_NAME "${CMAKE_HOST_SYSTEM_PROCESSOR}")
endif()
if(PACKAGE_ARCH_NAME STREQUAL "")
  set(PACKAGE_ARCH_NAME "unknown")
endif()
string(TOLOWER "${PACKAGE_ARCH_NAME}" PACKAGE_ARCH_NAME)

set(CPACK_GENERATOR "ZIP")
set(CPACK_PACKAGE_NAME "${PROJECT_NAME}")
set(CPACK_PACKAGE_VENDOR "MADS")
set(CPACK_PACKAGE_VERSION "${PROJECT_VERSION}")
set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY ON)
set(CPACK_PACKAGE_FILE_NAME
  "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${PACKAGE_OS_NAME}-${PACKAGE_ARCH_NAME}")
include(CPack)