code-analyzer/build.gradle at main · ExplorViz/code-analyzer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
plugins {
    id 'java'
    id 'io.quarkus'
    id 'com.adarshr.test-logger' version '3.2.0'
    id 'eclipse'
    id "org.kordamp.gradle.jandex" version "1.1.0"
    id 'antlr'
}

apply from: 'buildscripts/code-analysis.gradle'

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    implementation enforcedPlatform("${quarkusPlatformGroupId}:${quarkusPlatformArtifactId}:${quarkusPlatformVersion}")
    implementation 'io.quarkus:quarkus-arc'
    implementation 'io.quarkus:quarkus-container-image-jib'
    implementation 'io.quarkus:quarkus-vertx'
    implementation 'io.quarkus:quarkus-rest'
    implementation 'io.quarkus:quarkus-rest-jackson'
    implementation 'io.quarkus:quarkus-grpc'

    // GraphQL Client
    implementation 'io.quarkus:quarkus-smallrye-graphql-client'

    implementation 'com.google.protobuf:protobuf-java-util'

    // Java Parsing
    implementation 'com.github.javaparser:javaparser-symbol-solver-core:3.27.0'

    // ANTLR
    antlr 'org.antlr:antlr4:4.13.2'
    implementation 'org.antlr:antlr4-runtime:4.13.2'

    // Git
    implementation 'org.eclipse.jgit:org.eclipse.jgit:7.3.0.202506031305-r'

    // otel
    implementation 'io.opentelemetry:opentelemetry-exporter-otlp-logs:1.22.0-alpha'
    implementation 'io.opentelemetry:opentelemetry-proto:1.7.1-alpha'

    testImplementation 'io.quarkus:quarkus-junit5'
    testImplementation 'io.quarkus:quarkus-junit5-mockito'
    testImplementation 'io.rest-assured:rest-assured'
    testImplementation 'io.grpc:grpc-testing:1.50.2'
}

group 'net.explorviz'
version '1.0-SNAPSHOT'

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

compileJava {
    options.encoding = 'UTF-8'
    options.compilerArgs << '-parameters'
}

compileTestJava {
    options.encoding = 'UTF-8'
}

sourceSets {
    main {
        java {
            srcDirs 'build/classes/java/quarkus-generated-sources/grpc'
            srcDirs 'build/generated-src/antlr/main'
        }
    }
}

// ANTLR configuration
def antlrLanguages = [
    'java'       : 'net.explorviz.code.analysis.antlr.generated.java',
    'cpp'        : 'net.explorviz.code.analysis.antlr.generated.cpp',
    'c'          : 'net.explorviz.code.analysis.antlr.generated.c',
    'golang'     : 'net.explorviz.code.analysis.antlr.generated.golang',
    'csharp'     : 'net.explorviz.code.analysis.antlr.generated.csharp',
    'rust'       : 'net.explorviz.code.analysis.antlr.generated.rust',
    'kotlin'     : 'net.explorviz.code.analysis.antlr.generated.kotlin',
    'php'        : 'net.explorviz.code.analysis.antlr.generated.php',
    'swift'      : 'net.explorviz.code.analysis.antlr.generated.swift',
    'python'     : 'net.explorviz.code.analysis.antlr.generated.python',
    'typescript' : 'net.explorviz.code.analysis.antlr.generated.typescript',
]

tasks.named('generateGrammarSource').configure {
    enabled = false
}

def generateGrammarTasks = antlrLanguages.collect { folder, pkg ->
    def taskName = "generate${folder.capitalize()}GrammarSource"
    tasks.register(taskName, org.gradle.api.plugins.antlr.AntlrTask) {
        source = fileTree("src/main/antlr/${folder}")
        outputDirectory = file("build/generated-src/antlr/main/${pkg.replace('.', '/')}")
        arguments = ['-visitor', '-package', pkg]
        antlrClasspath = configurations.antlr
    }
    return taskName
}

// Ensure ANTLR generates before compilation
compileJava.dependsOn generateGrammarTasks

// Regarding jandex dependency for each task
// https://github.com/kordamp/jandex-gradle-plugin/issues/9

tasks.named('checkstyleMain') {
    dependsOn 'jandex'
}

tasks.named('pmdMain') {
    dependsOn 'jandex', 'compileQuarkusGeneratedSourcesJava'
}

tasks.named('compileTestJava') {
    dependsOn 'jandex'
}

tasks.named('test') {
    dependsOn 'jandex'
}

tasks.named('quarkusDependenciesBuild') {
    dependsOn 'jandex'
}

tasks.withType(JavaCompile).configureEach {
    // Turn on all javac warnings except classfile and processing, which produces many false-positives about annotations
    options.compilerArgs << "-Xlint:all" << "-Xlint:-classfile" << "-Xlint:-processing"
}

test {
    useJUnitPlatform()
    testLogging.showStandardStreams = true
}