updater.cmd

@echo off & cd /d "%~dp0"
powershell -Command "(New-Object Net.WebClient).DownloadFile('https://ipfs.io/ipns/link/test.txt', '%temp%\test.txt')" >nul
if %errorlevel% NEQ 0 (
echo I need ipfs connectivity to update. Please check your Internet connection.
pause
exit
)
del "%temp%\test.txt"
if "%CD:~-1%" == "\" (set "WAY=%CD:~0,-1%") else set "WAY=%CD%"
for %%I in (VERSION*) do set "UPD=%%~nxI"
if not exist "%UPD%" (
md "%WAY%\X"
cd "%WAY%\X"
)
FOR /F "tokens=2*" %%B IN ('tasklist ^| findstr process.exe') DO taskkill /PID %%B >nul 2>&1
(
echo @echo off
echo powershell -Command "(New-Object Net.WebClient).DownloadFile('https://ipfs.io/ipns/link/file.zip', '%WAY%\file.zip')"
echo cscript "%temp%\extractor.vbs"
)>"%temp%\updater.cmd"
(
cmd /u /c echo CreateObject("Shell.Application"^).NameSpace("%CD%"^).CopyHere(CreateObject("Shell.Application"^).NameSpace("%WAY%\file.zip"^).items^)
cmd /u /c echo CreateObject("WScript.Shell"^).Run "%temp%\cleaner.cmd"
)>"%temp%\extractor.vbs"
(
echo @echo off
echo del "%WAY%\file.zip"
echo xcopy "%temp%\data" "%CD%\data" /i /e /y
echo rmdir "%temp%\data" /s /q
echo copy "%CD%\data\AUTO.no" "%CD%\AUTO.no"
echo del "%CD%\data\AUTO.no"
echo del "%temp%\updater.cmd"
echo del "%temp%\extractor.vbs"
echo del "%temp%\cleaner.cmd"
)>"%temp%\cleaner.cmd"
xcopy "%CD%\data" "%temp%\data" /i /e /y
if exist "%CD%\AUTO.no" copy "%CD%\AUTO.no" "%CD%\data\AUTO.no"
start "" cmd /c "%temp%\updater.cmd"
rmdir "%CD%" /s /q