GA-render-cuda/project.pro at master · AngelTerrones/GA-render-cuda · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
# -------------------------------------------------------------------------------
# Project configuration.
# Created: 2015-09-22
# -------------------------------------------------------------------------------

QT += core gui svg

TARGET = render
DESTDIR = bin
TEMPLATE = app
CONFIG += warn_on debug qwt

SOURCES += \
    src/main.cpp \
    src/Chromosome.cpp

HEADERS += \
        src/Chromosome.hpp

OTHER_FILES += distance.cu

#QMAKE_CFLAGS+=-pg
#QMAKE_CXXFLAGS+=-pg
#QMAKE_LFLAGS+=-pg

OBJECTS_DIR = build
MOC_DIR     = build
RCC_DIR     = build
UI_DIR      = build
CUDA_OBJECTS_DIR = build

# CUDA
CUDA_SOURCES += src/distance.cu
CUDA_DIR = /opt/cuda
NVCC_OPTIONS = --use_fast_math -std=c++11 -Xcompiler -D__CORRECT_ISO_CPP11_MATH_H_PROTO -O2

# include paths
INCLUDEPATH += \
            $$CUDA_DIR/include \
            $$CUDA_DIR/samples/commom/inc

QMAKE_LIBDIR += $$CUDA_DIR/lib64
LIBS += -lcuda -lcudart

CONFIG(debug, debug|release){
    cuda_d.input = CUDA_SOURCES
    cuda_d.output = $$CUDA_OBJECTS_DIR/${QMAKE_FILE_BASE}_cuda.o
    cuda_d.commands = $$CUDA_DIR/bin/nvcc -D_DEBUG $$NVCC_OPTIONS $$CUDA_INCLUDE_PATHS $$LIBS -c -o ${QMAKE_FILE_OUT} ${QMAKE_FILE_NAME}
    cuda_d.dependency_type = TYPE_C
    QMAKE_EXTRA_COMPILERS += cuda_d
}
else{
    cuda_d.input = CUDA_SOURCES
    cuda_d.output = $$CUDA_OBJECTS_DIR/${QMAKE_FILE_BASE}_cuda.o
    cuda_d.commands = $$CUDA_DIR/bin/nvcc $$NVCC_OPTIONS $$CUDA_INCLUDE_PATHS $$LIBS -c -o ${QMAKE_FILE_OUT} ${QMAKE_FILE_NAME}
    cuda_d.dependency_type = TYPE_C
    QMAKE_EXTRA_COMPILERS += cuda_d
}