mapstruct-plugin/build.gradle at master · AkaZver/mapstruct-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
plugins {
    id 'com.vanniktech.maven.publish' version '0.37.0'
    id 'com.gradle.plugin-publish' version '2.1.1'
    id 'io.freefair.lombok' version '9.5.0'
    id 'org.sonarqube' version '7.3.1.8318'
    id 'java-gradle-plugin'
    id 'jacoco'
}

group = 'io.github.akazver'
version = System.getenv("RELEASE_VERSION") ?: "dev"

gradlePlugin {
    website = 'https://github.com/AkaZver'
    vcsUrl = 'https://github.com/AkaZver/mapstruct-plugin'

    plugins {
        mapstruct {
            id = 'io.github.akazver.mapstruct'
            displayName = 'MapStruct Plugin'
            description = 'Automatic MapStruct configuration'
            implementationClass = 'io.github.akazver.gradle.plugins.mapstruct.MapstructPlugin'
            tags.set(['mapstruct', 'mapping', 'lombok', 'spring', 'quarkus', 'camel', 'protobuf'])
        }
    }
}

repositories {
    mavenLocal()
    mavenCentral()
    gradlePluginPortal()
}

dependencies {
    // id 'io.freefair.lombok' version '9.5.0'
    testImplementation 'io.freefair.gradle:lombok-plugin:9.5.0'
    // id 'io.quarkus' version '3.38.0'
    testImplementation 'io.quarkus:io.quarkus.gradle.plugin:3.38.0'
    // id 'org.springframework.boot' version '4.1.0'
    testImplementation 'org.springframework.boot:org.springframework.boot.gradle.plugin:4.1.0'
    // id 'com.google.protobuf' version '0.10.0'
    testImplementation 'com.google.protobuf:com.google.protobuf.gradle.plugin:0.10.0'
    // id 'org.jetbrains.kotlin.jvm' version '2.0.21'
    testImplementation 'org.jetbrains.kotlin:kotlin-gradle-plugin:2.0.21'

    testImplementation 'org.assertj:assertj-core:3.27.7'
    testImplementation 'org.junit.jupiter:junit-jupiter:6.1.2'
    testImplementation 'org.junit.platform:junit-platform-launcher:6.1.2'
    testImplementation 'org.mockito:mockito-core:5.23.0'
    testImplementation 'org.mockito:mockito-junit-jupiter:5.23.0'
}

test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
    maxParallelForks = 1
    jvmArgs '-Xshare:off'
}

configurations.testImplementation {
    exclude group: 'org.slf4j'
    exclude group: 'org.jboss.slf4j'
}

java {
    sourceCompatibility = 17
    targetCompatibility = 17
    withSourcesJar()
}

jacocoTestReport {
    dependsOn test

    reports {
        xml.required = true
    }
}

sonarqube {
    properties {
        property "sonar.projectKey", "AkaZver_mapstruct-plugin"
        property "sonar.organization", "aka-zver"
        property "sonar.host.url", "https://sonarcloud.io"
        property "sonar.java.binaries", "build/classes/java/main"
        property "sonar.java.test.binaries", "build/classes/java/test"
    }
}

mavenPublishing {
    publishToMavenCentral(true)
    signAllPublications()

    pom {
        name = 'MapStruct Plugin'
        description = 'Automatic MapStruct configuration for Gradle'
        inceptionYear = '2021'
        url = 'https://github.com/AkaZver/mapstruct-plugin'

        licenses {
            license {
                name = 'The Apache License, Version 2.0'
                url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                distribution = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
            }
        }

        developers {
            developer {
                id = 'akazver'
                name = 'Vasiliy Sobolev'
                email = 'aka.zver.007@gmail.com'
                url = 'https://github.com/AkaZver'
            }
        }

        scm {
            url = 'https://github.com/AkaZver/mapstruct-plugin'
            connection = 'scm:git:git://github.com/AkaZver/mapstruct-plugin.git'
            developerConnection = 'scm:git:ssh://github.com/AkaZver/mapstruct-plugin.git'
        }
    }
}

javadoc {
    options.addStringOption('Xdoclint:none', '-quiet')
}