link/cmake_include/ConfigureAbletonLink.cmake at master · Ableton/link · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
cmake_minimum_required(VERSION 3.16)

function(link_pin_win32_winnt target)
  if(WIN32)
    target_compile_definitions(${target} PRIVATE _WIN32_WINNT=0x0601)
  endif()
endfunction()

function(ConfigureAbletonLink PATH_TO_LINK)
  add_library(Ableton::Link IMPORTED INTERFACE)
  set_property(TARGET Ableton::Link APPEND PROPERTY
    INTERFACE_INCLUDE_DIRECTORIES
    ${PATH_TO_LINK}/include
  )

  if(UNIX)
    set_property(TARGET Ableton::Link APPEND PROPERTY
      INTERFACE_COMPILE_DEFINITIONS
      LINK_PLATFORM_UNIX=1
    )
  endif()

  if(APPLE)
    set_property(TARGET Ableton::Link APPEND PROPERTY
      INTERFACE_COMPILE_DEFINITIONS
      LINK_PLATFORM_MACOSX=1
  )
  elseif(WIN32)
    set_property(TARGET Ableton::Link APPEND PROPERTY
      INTERFACE_COMPILE_DEFINITIONS
      LINK_PLATFORM_WINDOWS=1
    )
    set_property(TARGET Ableton::Link APPEND PROPERTY
      INTERFACE_COMPILE_DEFINITIONS
      INCL_EXTRA_HTON_FUNCTIONS=1
    )
    elseif(CMAKE_SYSTEM_NAME MATCHES "Linux|kFreeBSD|GNU|Android")
      set_property(TARGET Ableton::Link APPEND PROPERTY
        INTERFACE_COMPILE_DEFINITIONS
        LINK_PLATFORM_LINUX=1
    )
    if(ANDROID)
      # On Android, pthread is part of libc; there is no separate libpthread.
      set_property(TARGET Ableton::Link APPEND PROPERTY
      INTERFACE_LINK_LIBRARIES
        atomic
      )
    else()
      set_property(TARGET Ableton::Link APPEND PROPERTY
      INTERFACE_LINK_LIBRARIES
        atomic
        pthread
      )
    endif()
  endif()

  include(${PATH_TO_LINK}/cmake_include/ConfigureAsioStandalone.cmake)
    ConfigureAsioStandalone(${PATH_TO_LINK})
    set_property(TARGET Ableton::Link APPEND PROPERTY
      INTERFACE_LINK_LIBRARIES
      AsioStandalone::AsioStandalone
    )

  set_property(TARGET Ableton::Link APPEND PROPERTY
    INTERFACE_SOURCES
    ${PATH_TO_LINK}/include/ableton/Link.hpp
  )
endfunction()