oxbow/flake.nix at master · 3L0C/oxbow · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
{
  description = "oxbow, a dynamic window manager for the Wayland compositor River, written in OCaml";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    git-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      ...
    }@inputs:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      forAllSystems =
        f:
        nixpkgs.lib.genAttrs systems (
          system: f system (nixpkgs.legacyPackages.${system}.extend self.overlays.default)
        );
    in
    {
      packages = forAllSystems (_: pkgs: { default = pkgs.oxbow; });

      formatter = forAllSystems (_: pkgs: pkgs.nixfmt);

      checks = forAllSystems (
        _: pkgs:
        (import ./checks.nix {
          inherit inputs pkgs;
          ocamlformat = pkgs.ocamlPackages.ocamlformat;
        })
        // {
          package-default = pkgs.oxbow;
        }
      );

      devShells = forAllSystems (
        system: pkgs: {
          default = import ./shell.nix {
            inherit pkgs;
            checks = self.checks.${system};
          };
        }
      );

      overlays.default = import ./nix/overlay.nix;
    };
}